Wolfram Language™

Tunnels

TunnelData fournit des informations sur les tunnels, tels que la longueur et le lieu.

In[1]:=

tunnels = TunnelData[];

In[2]:=

Length[tunnels]

Out[2]=

Pour chaque tunnel, trouvez sa longueur et sa localisation donnés par le ou les pays.

In[3]:=

rawData = TunnelData[tunnels, {"Countries", "Length"}];

Nettoyez les données pour éliminer les valeurs manquantes.

In[4]:=

data = DeleteMissing[rawData, 1, 2];

Convertissez les données de longueur en miles.

In[5]:=

data[[All, 2]] = UnitConvert[N[data[[All, 2]]], "Miles"];

In[6]:=

lengths = data[[All, 2]];

In[7]:=

MinMax[lengths]

Out[7]=

In[8]:=

h = Histogram[lengths, {1, 12, .5}, PDF, FrameLabel -> Automatic, PlotTheme -> "Detailed"]

Out[8]=

Les données peuvent être décrites par un mélange de distributions à longue queue.

In[9]:=

dist = MixtureDistribution[{w1, w2}, {ParetoDistribution[a1, a2, a3, a4], WeibullDistribution[b1, b2]}];

In[10]:=

edist = EstimatedDistribution[lengths, dist]

Out[10]=

Testez la qualité d'ajustement contre les distributions de mélange de famille paramétrique.

In[11]:=

DistributionFitTest[lengths, dist, "TestDataTable"]

Out[11]=

Tracez la densité de probabilité de la distribution ajustée contre l'histogramme.

In[12]:=

Show[h, Plot[PDF[edist, Quantity[x, "Miles"]], {x, 1, 12}, PlotRange -> All] // Quiet]

Out[12]=

Visualisez les locations des tunnels.

Groupez par pays.

In[13]:=

res = GroupBy[data, First, Flatten[Take[#, All, -1]] &];

Certains tunnels sont situés dans plus d'un pays.

In[14]:=

shared = Select[Keys[res], Length[#] > 1 &]

Out[14]=

Distribuez les tunnels partagés et choisissez les pays qui ont au moins 10 tunnels. Tracez le tableau de distribution de longueur.

In[15]:=

split = GroupBy[ Flatten[Map[{{{#[[1]]}, res[#]}, {{#[[2]]}, res[#]}} &, shared], 1], First, Flatten[#[[All, 2]]] &];

In[16]:=

together = Join[KeyDrop[res, shared], split, 2];

In[17]:=

tc = SortBy[Select[Normal[together], Length[#[[2]]] >= 10 &], Length@*Last];

In[18]:=

DistributionChart[tc[[All, 2]], ChartLabels -> tc[[All, 1, 1]], BarOrigin -> Left, BarSpacing -> .3, FrameLabel -> {"Miles"}, LabelingFunction -> (Placed[Length[#1], After] &), ChartStyle -> "SandyTerrain", ImageSize -> Large]

Out[18]=

Le kilométrage total du tunnel par pays avec les tunnels partagés inclus en longueur totale pour chaque pays.

In[19]:=

vals = KeyMap[First, Map[Total, together]]; title = Style["tunnel mileage", 24, Bold, GrayLevel[.2], FontFamily -> "Osaka"]; GeoRegionValuePlot[vals, GeoProjection -> "Mercator", GeoRange -> {{-65, 80}, {-170, 190}}, PlotLegends -> Automatic, ColorFunction -> (ColorData["StarryNightColors", 2 #] &), Epilog -> Inset[title, {30, -65}], ImageSize -> 500]

Out[19]=