美国联邦存款保险公司组织数据
美国联邦存款保险公司（FDIC）是一个管理美国金融机构存款的独立美国政府机构. 目前，加盟机构的存款有最高 $250,000 的保险. 在此，对加盟机构的资产、大小分布和地理分散进行了研究.
首先, 加载作为 ResourceObject 的 FDIC 数据实体库.
In[1]:=
fdic = ResourceData[
ResourceObject[
Association[
"Name" -> "FDIC Institution EntityStore",
"UUID" -> "6f5d37d4-1406-483c-b67c-f58d903d16b1",
"ResourceType" -> "DataResource", "Version" -> "1.0.0",
"Description" -> "A Wolfram Language EntityStore with selected \
data on FDIC insured institutions",
"ContentSize" -> Quantity[0, "Bytes"],
"ContentElements" -> {"EntityStore"}]]]Out[1]=
注册该部分数据库.
In[2]:=
PrependTo[$EntityStores, fdic];计算 FDIC 机构数目.
In[3]:=
Length[ents = EntityList["FDICInstitution"]]Out[3]=
列举实体库中可用的属性.
In[4]:=
EntityProperties["FDICInstitution"] // Sort // Take[#, 20] &Out[4]=
可视化 FDIC 相关银行的地理位置.
In[5]:=
GeoListPlot[EntityList["FDICInstitution"], PlotMarkers -> "$"]Out[5]=
在对数-对数图中显示排名分布.
In[6]:=
ListLogLogPlot[
Reverse@Sort[EntityValue["FDICInstitution", "TotalAssets"]],
AxesLabel -> Automatic, PlotStyle -> PointSize[Medium]]Out[6]=
职员与资产绘图.
In[7]:=
empVsAssets =
EntityValue[
"FDICInstitution", {"TotalEmployeeNumber", "TotalAssets"}];In[8]:=
ListLogLogPlot[empVsAssets, AxesLabel -> Automatic]Out[8]=
标注最大的六个机构.
显示完整的 Wolfram 语言输入
Out[9]=
债务与资产绘图.
In[10]:=
assetsVsLiability =
EntityValue["FDICInstitution", {"TotalAssets", "TotalLiabilities"}];In[11]:=
ListLogLogPlot[assetsVsLiability, AxesLabel -> Automatic]Out[11]=
将贷款净额和租赁相对各项存款连同一同拟合绘图.
In[12]:=
loanVsDeposit =
EntityValue[
"FDICInstitution", {"NetLoansAndLeases", "TotalDeposits"}];In[13]:=
nmf = NonlinearModelFit[
Select[QuantityMagnitude /@ loanVsDeposit, Min[#] > 0 &],
c + a x^\[Alpha], {a, \[Alpha], c}, x]Out[13]=
In[14]:=
Show[ListPlot[loanVsDeposit],
Plot[Evaluate[Normal[nmf]], {x, 0, 10^10}, PlotStyle -> Red,
AxesLabel -> Automatic]]Out[14]=
将等级 1（安全）和等级 2（高风险）资产与总资产相对比.
In[15]:=
{tierOneCapitalToAssets,
tierTwoCapitalToAssetsCapitalToAssets} = (Divide @@@
EntityValue[
"FDICInstitution", {#, "TotalAssets"}]) & /@ {"TierOneCapital",
"TierTwoRiskBasedCapital"};In[16]:=
Histogram[{tierOneCapitalToAssets,
tierTwoCapitalToAssetsCapitalToAssets}, {0, 0.3, 0.01},
ChartLegends -> {"Tier 1", "Tier 2"},
PlotLabel -> "Capital/Assets Ratio"]Out[16]=
提取资产分布作为 "EntityAssociation".
In[17]:=
dat = EntityValue["FDICInstitution", "TotalAssets",
"EntityAssociation"];资产分布的绘图.
In[18]:=
Histogram[dat, "Log", AxesLabel -> Automatic]Out[18]=
显示资产超过 50 到 3000 亿美金的银行地址.
In[19]:=
GeoListPlot[
Keys[Select[dat,
GreaterThan[Quantity[#, "USDollars"]]]]] & /@ {5*^9, 300*^9}Out[19]=
用图形显示所持资产超过其余 6121 家银行总和的前 10 家银行.
显示完整的 Wolfram 语言输入
Out[20]=
找出拥有最高存储的 1% 的银行.
In[21]:=
dat1 = EntityValue["FDICInstitution", "TotalDeposits",
"EntityAssociation"];In[22]:=
{bottom1percent, top1percent} =
Quantile[values = Values[dat1], {0.01, 0.99}]Out[22]=
将其绘制在地图上.
In[23]:=
GeoListPlot[Keys[Select[dat1, GreaterThan[top1percent]]]]Out[23]=
每个城市的资产分布和本福特（Benford）定律有着显著程度的一致.
显示完整的 Wolfram 语言输入
Out[25]=
显示拥有最高财务杠杆的银行.
显示完整的 Wolfram 语言输入
In[27]:=
dataSet3[TakeLargestBy["FinancialLeverage", 10]]Out[27]=
绘制财务杠杆分布图.
In[28]:=
Histogram[dataSet3[All, "FinancialLeverage"], {0, 20, 0.5},
PlotLabel -> "FDIC banks Financial Leverage distribution"]Out[28]=
通过图形研究资产、长期资产和负债的关系.
显示完整的 Wolfram 语言输入
Out[33]=
