Wolfram Language™

Données institutionnelles de la Federal Deposit Insurance Corporation

La Federal Deposit Insurance Corporation (FDIC) est une agence gouvernementale américaine indépendante chargée d'assurer les transferts de fonds dans les institutions financières américaines. Actuellement, les transferts de fonds dans les institutions membres sont assurés jusqu'à 250 000 dollars. Nous étudions ici les avoirs, la répartition par taille et la dispersion géographique des institutions membres.

Tout d'abord, chargez un magasin d'entités de données FDIC en tant que ResourceObject.

In[1]:=

fdic = ResourceData[ ResourceObject[ Association[ "Name" -> "FDIC Institution EntityStore", "UUID" -> "6f5d37d4-1406-483c-b67c-f58d903d16b1", "ResourceType" -> "DataResource", "Version" -> "1.0.0", "Description" -> "A Wolfram Language EntityStore with selected \ data on FDIC insured institutions", "ContentSize" -> Quantity[0, "Bytes"], "ContentElements" -> {"EntityStore"}]]]

Out[1]=

Enregistrez le magasin pour cette session.

In[2]:=

PrependTo[$EntityStores, fdic];

Comptez le nombre d'institutions FDIC.

In[3]:=

Length[ents = EntityList["FDICInstitution"]]

Out[3]=

Listez quelques-unes des propriétés disponibles dans le magasin d'entités.

In[4]:=

EntityProperties["FDICInstitution"] // Sort // Take[#, 20] &

Out[4]=

Visualisez les emplacements géographiques des banques affiliées à la FDIC.

In[5]:=

GeoListPlot[EntityList["FDICInstitution"], PlotMarkers -> "$"]

Out[5]=

Affichez la répartition des rangs dans un diagramme log-log.

In[6]:=

ListLogLogPlot[ Reverse@Sort[EntityValue["FDICInstitution", "TotalAssets"]], AxesLabel -> Automatic, PlotStyle -> PointSize[Medium]]

Out[6]=

Tracez la courbe des employés en fonction des actifs.

In[7]:=

empVsAssets = EntityValue[ "FDICInstitution", {"TotalEmployeeNumber", "TotalAssets"}];

In[8]:=

ListLogLogPlot[empVsAssets, AxesLabel -> Automatic]

Out[8]=

Étiquetez les six institutions les plus importantes.

In[9]:=

ListLogLogPlot[ Callout[{#2, #3}, #1] & @@@ EntityValue[ EntityList[ EntityClass["FDICInstitution", "TotalAssets" -> TakeLargest[6]]], {"Label", "TotalEmployeeNumber", "TotalAssets"}], PlotRangePadding -> Scaled[0.25], AxesLabel -> {"employee count", "assets"}]

Out[9]=

Tracez les passifs en fonction des actifs.

In[10]:=

assetsVsLiability = EntityValue["FDICInstitution", {"TotalAssets", "TotalLiabilities"}];

In[11]:=

ListLogLogPlot[assetsVsLiability, AxesLabel -> Automatic]

Out[11]=

Tracez les prêts nets et le crédit-bail en fonction du total des transferts de fonds, ainsi qu'un ajustement.

In[12]:=

loanVsDeposit = EntityValue[ "FDICInstitution", {"NetLoansAndLeases", "TotalDeposits"}];

In[13]:=

nmf = NonlinearModelFit[ Select[QuantityMagnitude /@ loanVsDeposit, Min[#] > 0 &], c + a x^\[Alpha], {a, \[Alpha], c}, x]

Out[13]=

In[14]:=

Show[ListPlot[loanVsDeposit], Plot[Evaluate[Normal[nmf]], {x, 0, 10^10}, PlotStyle -> Red, AxesLabel -> Automatic]]

Out[14]=

Comparez les fonds propres de catégorie 1 (sûrs) et de catégorie 2 (plus risqués) au total des actifs.

In[15]:=

{tierOneCapitalToAssets, tierTwoCapitalToAssetsCapitalToAssets} = (Divide @@@ EntityValue[ "FDICInstitution", {#, "TotalAssets"}]) & /@ {"TierOneCapital", "TierTwoRiskBasedCapital"};

In[16]:=

Histogram[{tierOneCapitalToAssets, tierTwoCapitalToAssetsCapitalToAssets}, {0, 0.3, 0.01}, ChartLegends -> {"Tier 1", "Tier 2"}, PlotLabel -> "Capital/Assets Ratio"]

Out[16]=

Récupérez la répartition des actifs en tant qu'"EntityAssociation".

In[17]:=

dat = EntityValue["FDICInstitution", "TotalAssets", "EntityAssociation"];

Tracez la répartition des actifs.

In[18]:=

Histogram[dat, "Log", AxesLabel -> Automatic]

Out[18]=

Affichez l'emplacement des banques dont les actifs sont supérieurs à 5 milliards et à 300 milliards de dollars.

In[19]:=

GeoListPlot[ Keys[Select[dat, GreaterThan[Quantity[#, "USDollars"]]]]] & /@ {5*^9, 300*^9}

Out[19]=

Découvrez graphiquement que les 10 premières banques détiennent plus d'actifs que les 6121 autres réunies.

In[20]:=

With[{atas = QuantityMagnitude[ EntityValue["FDICInstitution", EntityProperty["FDICInstitution", "AverageTotalAssets"]]]}, ListLogLogPlot[100 Accumulate[Reverse[Sort[atas]]]/Total[atas], PlotRange -> All, GridLines -> Automatic, PlotStyle -> PointSize[Medium], AxesLabel -> {None, Quantity[None, "Percent"]}]]

Out[20]=

Trouvez les banques ayant les 1 % de transferts de fonds les plus élevés.

In[21]:=

dat1 = EntityValue["FDICInstitution", "TotalDeposits", "EntityAssociation"];

In[22]:=

{bottom1percent, top1percent} = Quantile[values = Values[dat1], {0.01, 0.99}]

Out[22]=

Tracez-les sur une carte.

In[23]:=

GeoListPlot[Keys[Select[dat1, GreaterThan[top1percent]]]]

Out[23]=

La répartition des actifs par ville répond de manière remarquable à la loi de Benford.

In[24]:=

$percity = Reverse[SortBy[{#[[1, 1]], Total[#[[All, -1]]]} & /@ Normal[Normal[ DeleteMissing[ SortBy[GroupBy[ EntityValue["FDICInstitution", {"City", "TotalAssets"}], First] , Length], 1, 3]][[All, -1]]], Last]];

In[25]:=

ListPlot[{Tally[ IntegerDigits[Round[QuantityMagnitude[#2]]][[1]] & @@@ $percity], Table[{d, Length[$percity] Log10[1 + 1/d]}, {d, 1, 9}]}, PlotRange -> All, Filling -> Axis, PlotLegends -> {"total assets", "Benford"}]

Out[25]=

Affichez les banques ayant le plus important pouvoir d'achat financier.

In[26]:=

dataSet3 = Append[#, <| "FinancialLeverage" -> N[#TotalLiabilities/#TotalEquity]|>] & /@ EntityValue[ "FDICInstitution", {"Position", "TotalLiabilities", "TotalEquity"}, "Dataset"];

In[27]:=

dataSet3[TakeLargestBy["FinancialLeverage", 10]]

Out[27]=

Tracez la répartition des pouvoirs d'achat financiers.

In[28]:=

Histogram[dataSet3[All, "FinancialLeverage"], {0, 20, 0.5}, PlotLabel -> "FDIC banks Financial Leverage distribution"]

Out[28]=

Explorez graphiquement la relation entre les actifs, les actifs à long terme et les passifs.

In[29]:=

props = {EntityProperty["FDICInstitution", "TotalAssets"], EntityProperty["FDICInstitution", "LongTermAssets"], EntityProperty["FDICInstitution", "TotalLiabilities"]}; data = Select[ N@QuantityMagnitude@ DeleteMissing[ EntityValue["FDICInstitution", Append[props, "Entity"]], 1, 2], Min[Most[#]] > 0 &];

In[30]:=

data2 = Select[{#1/#2, #1/#3, #4} & @@@ data, Between[{0, 15}][#[[1]]] && Between[{1, 1.4}][#[[2]]] &];

In[31]:=

sdk = SmoothKernelDistribution[Most /@ data2];

In[32]:=

label[{a_, b_, c_, _[d_]}] := Column[{d, Grid[Transpose[{props, Quantity[NumberForm[#, 4], "USDollars"] & /@ {a, b, c}}], Dividers -> Center]}]

In[33]:=

ContourPlot[PDF[sdk, {x, y}], {x, 0, 15}, {y, 1, 1.4}, PlotRange -> All, Contours -> 50, ContourStyle -> None, ColorFunction -> (Lighter[ColorData["AvocadoColors"][#], 0.5] &), FrameLabel -> {"total asssets"/"long term assets", "total asssets"/"total liabilities"}, Epilog -> ({ColorData["DarkRainbow"][(Log10[#1] - 7)/5], PointSize[0.00125], Point[{#1/#2, #1/#3}]} & @@@ data)]

Out[33]=