Wolfram Language™

Poder de um Pokémon

A Wolfram Knowledgebase contém informações sobre ícones da cultura popular, assim como conhecimento científico. Aqui, várias características físicas (pontos de ataque e defesa, peso, cor) da coleção de Pokémon são exploradas, contrastadas, e visualizadas usando um framework de entidades embutidas.

Faça um gráfico das distribuições de pontos de ataque e de defesa de todos os Pokémons.

In[1]:=

PairedHistogram[EntityValue["Pokemon", "Attack"], EntityValue["Pokemon", "Defense"], ChartLabels -> {"attack", "defense"}, ChartStyle -> {{LightOrange, LightBlue}, None}]

Out[1]=

Crie um Dataset de pontos de ataque versus defesa para a geração VI de Pokémons e faça um gráfico de um contra o outro.

In[2]:=

stat = EntityValue[Entity[ "Pokemon", { "Generation" -> Entity[ "PokemonGeneration", "GenerationVI"]}], {"Attack", "Defense"}, "Dataset"];

In[3]:=

ListPlot[stat, PlotStyle -> Directive[Opacity[0.5], Orange, PointSize[Medium]], AxesLabel -> Automatic, LabelingFunction -> None]

Out[3]=

Compare e faça um gráfico dos pesos médios dos Pokémon de diferentes gerações.

In[4]:=

wg = Normal[ GroupBy[Rule @@@ EntityValue["Pokemon", {"Generation", "Weight"}], First -> Last, Mean]]

Out[4]=

In[5]:=

BarChart3D[wg[[All, 2]], ChartLegends -> wg[[All, 1]], ChartStyle -> 24]

Out[5]=

Use uma classe de entidade definida implicitamente para encontrar os três Pokémons mais pesado.

In[6]:=

EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]]

Out[6]=

In[7]:=

EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]]; EntityValue[%, "Generation"]

Out[7]=

Use uma classe de entidade definida implicitamente para encontrar o Pokémon amarelo que pesa entre 50 e 100 kg.

In[8]:=

yellowMidweights = EntityList[ Entity["Pokemon", {"PokedexColor" -> "Yellow", "Weight" -> Between[{ Quantity[50, "Kilograms"], Quantity[100, "Kilograms"]}]}]]

Out[8]=

Crie uma colagem desses personagens de Pokémon com tamanhos de acordo com seus pesos.

In[9]:=

ImageCollage[ Rule @@@ EntityValue[yellowMidweights, {"Weight", "Image"}], Background -> White]

Out[9]=

Compare as cores de Pokémons nos grupos originais (Geração I) e nos grupos mais novos (Geração VI).

In[10]:=

{color1, color6} = Sort[Tally[EntityValue[EntityList[ Entity["Pokemon", {"Generation" -> Entity["PokemonGeneration", #]}]], "PokedexColor"]]] & /@ {"GenerationI", "GenerationVI"};

In[11]:=

PieChart3D[{color1[[All, 2]], color6[[All, 2]]}, PlotLabel -> "Gen. I (outer) vs. Gen. VI (inner)", ChartElementFunction -> "ProfileSector3D", SectorOrigin -> {Automatic, 1}, ChartStyle -> (color1[[All, 1]] /. co_Entity :> Symbol[co[[2]]]), ChartLegends -> color1[[All, 1]]]

Out[11]=