Wolfram Language™

Os números da maratona de Chicago de 2015

A Maratona de Chicago em 2015 atraiu 45.000 corredores para Chicago em 11 de Outubro de 2015. Mais de 37.000 completaram a prova, e detalhes do desempenho de cada corredor foram cuidadosamente registrados. Explore e visualize as características dos corredores e os seus desempenhos usando um banco de entidades personalizado que contém esses dados.

Carregue um banco de dados de entidades da maratona de um ResourceObject.

In[1]:=

marathonEntityStore = ResourceData[ ResourceObject[ Association[ "Name" -> "2015 Chicago Marathon Data", "UUID" -> "7dc77972-cfc3-48dc-8d08-0292c6d2a929", "ResourceType" -> "DataResource", "Version" -> "1.0.0", "Description" -> "2015 Chicago Marathon participant data", "ContentSize" -> Quantity[1990.2215919999999`, "Megabytes"], "ContentElements" -> {"Content"}]]]

Out[1]=

Registre o banco de dados para esta sessão.

In[2]:=

PrependTo[$EntityStores, marathonEntityStore];

Extraia os número total de corredores e, usando uma classe de entidade definida implicitamente, o número de participantes masculinos e femininos.

In[3]:=

EntityValue["ChicagoMarathon2015", "EntityCount"]

Out[3]=

In[4]:=

Table[EntityValue[ EntityClass["ChicagoMarathon2015", "Gender" -> gender], "EntityCount"], {gender, {Entity["Gender", "Male"], Entity["Gender", "Female"]}}]

Out[4]=

Selecione cinco corredores aleatóriamente.

In[5]:=

RandomEntity["ChicagoMarathon2015", 5]

Out[5]=

Veja as propriedades armazenadas para um corredor específico.

In[6]:=

Entity["ChicagoMarathon2015", "Runner145"]["PropertyAssociation"]

Out[6]=

Extraia as contagens de nacionalidades dos corredores e faça uma tabela das nacionalidades mais comuns.

In[7]:=

nationalityTallies = Reverse[SortBy[ Tally[EntityValue["ChicagoMarathon2015", EntityProperty["ChicagoMarathon2015", "Country"]]], Last]];

In[8]:=

TextGrid[Join @@@ Transpose[ Partition[Take[Reverse[Sort[Reverse /@ nationalityTallies]], 80], 20]], Alignment -> {{{Decimal, Left}}, Automatic}, Dividers -> {{{Thick, True}}, {{True}}}, Frame -> Thick, Background -> {Automatic, {{LightBlue, None}}}] // TraditionalForm

Out[8]//TraditionalForm=

Visualize as rotas geodésicas de todos os países de origem até Chicago.

In[9]:=

With[{chicago = Entity["City", {"Chicago", "Illinois", "UnitedStates"}]}, GeoGraphics[{Darker[Green], GeoPath[{chicago, #} & /@ nationalityTallies[[All, 1]], "Geodesic"]}, GeoRange -> "World", GeoProjection -> "Robinson", GeoCenter -> chicago]]

Out[9]=

Construa um heat map (mapa de "pontos quentes") dos EUA mostrando locais de origem para os participantes americanos.

In[10]:=

anyUS = EntityClass["ChicagoMarathon2015", "Country" -> Entity["Country", "UnitedStates"]] // EntityList;

In[11]:=

allUSCities = DeleteMissing[ EntityValue[anyUS, EntityProperty["ChicagoMarathon2015", "CityState"]]]; talliedUSCities = Tally[allUSCities]; coordsUS = EntityValue[talliedUSCities[[All, 1]], "Position"]; cityPositions = Transpose[{coordsUS, talliedUSCities[[All, -1]]^0.5}]; projectionUS = {"LambertAzimuthal", "Centering" -> GeoPosition[{37.1558, -95.883}]}; data = {GeoGridPosition[#1, projectionUS][[1]], #2} & @@@ cityPositions; weightedData = WeightedData @@ Transpose[data]; cityDensityP = SmoothKernelDistribution[weightedData, "Silverman"]; cityDensity[{lat_Real, lon_Real}] := With[{xy = First[GeoGridPosition[GeoPosition[{lat, lon}], projectionUS]]}, Flatten[{xy, PDF[cityDensityP, xy]}]]; area = GeoVariant[Entity["Country", "UnitedStates"], "DefaultMapArea"]; {{latminUS, latmaxUS}, {lonminUS, lonmaxUS}} = GeoBounds[area];

In[11]:=

cityPlot = ContourPlot[ Sqrt[Last[cityDensity[{lat, lon}]]], {lon, lonminUS, lonmaxUS}, {lat, latminUS, latmaxUS}, Frame -> False, PlotRange -> All, Contours -> 100, MaxRecursion -> 2, ColorFunction -> ColorData["DarkRainbow"], PlotRangePadding -> 0, ContourStyle -> None];

In[11]:=

GeoGraphics[{GeoStyling[{"GeoImage", cityPlot}], Polygon[area], Gray, Opacity[1], PointSize[0.001], Point[coordsUS]}, GeoRange -> area]

Out[12]=

Saiba o número de corredores por variação da média de divisão.

In[13]:=

allkm = Table[ Normal[allTimeSplits[[i]][2 ;;, "Time"]], {i, Length[allTimeSplits]}];

In[13]:=

allsplitbins = DeleteMissing[Transpose[allkm], 2];

In[13]:=

meanall = Table[N[Mean[allsplitbins[[i]]]], {i, Length[allsplitbins]}]

Out[13]=

In[13]:=

marathondistances = (allTimeSplits[[1]])[All, "Split"] // Normal

Out[13]=

In[13]:=

differencesall = Table[{marathondistances[[i + 1]], allsplitbins[[i]] - meanall[[i]]}, {i, Length[allsplitbins]}];

In[13]:=

allHistograms = Histogram[#2, {60}, PlotLabel -> NumberForm[#1, {3, 1}]] & @@@ differencesall;

Gere histogramas para cada divisão.

In[14]:=

Grid[Partition[allHistograms, UpTo[3]]]

Out[15]=

Faça um gráfico de uma distribuição de kernel suave das diferenças entre divisões de corredores e médias.

In[16]:=

skd = Table[ SmoothKernelDistribution[ QuantityMagnitude[differencesall[[i, 2]]]], {i, Length[differencesall]}];

In[17]:=

Plot[ Evaluate[Table[PDF[skd[[i]], t], {i, Length[skd]}]], {t, -8000, 10000}, PlotRange -> All, PlotLegends -> Table[If[IntegerQ[QuantityMagnitude[diff = differencesall[[i, 1]]]], diff, Round[diff, .1]], {i, Length[differencesall]}] ]

Out[17]=