Wolfram 언어

풍부한 Knowledgebase 액세스

포켓몬 파워

Wolfram Knowledgebase는 과학 지식뿐만 아니라 대중적인 문화 아이콘에 대한 정보도 내재하고 있습니다. 여기에서는 임베드된 엔티티 프레임워크를 사용하여 다양한 포켓몬의 여러가지 물리적 특성 (공격과 방어 지점, 무게, 색상)을 연구, 비교, 및 가시화 하고있습니다.

모든 포켓몬의 공격 지점과 방어 지점의 분포를 플롯합니다.

In[1]:=
Click for copyable input
PairedHistogram[EntityValue["Pokemon", "Attack"], EntityValue["Pokemon", "Defense"], ChartLabels -> {"attack", "defense"}, ChartStyle -> {{LightOrange, LightBlue}, None}]
Out[1]=

4세대 포켓몬의 공격 지점과 방어 지점의 Dataset을 생성하고 플롯합니다.

In[2]:=
Click for copyable input
stat = EntityValue[Entity[ "Pokemon", { "Generation" -> Entity[ "PokemonGeneration", "GenerationVI"]}], {"Attack", "Defense"}, "Dataset"];
In[3]:=
Click for copyable input
ListPlot[stat, PlotStyle -> Directive[Opacity[0.5], Orange, PointSize[Medium]], AxesLabel -> Automatic, LabelingFunction -> None]
Out[3]=

포켓몬의 평균 체중을 세대별로 비교하고 플롯합니다.

In[4]:=
Click for copyable input
wg = Normal[ GroupBy[Rule @@@ EntityValue["Pokemon", {"Generation", "Weight"}], First -> Last, Mean]]
Out[4]=
In[5]:=
Click for copyable input
BarChart3D[wg[[All, 2]], ChartLegends -> wg[[All, 1]], ChartStyle -> 24]
Out[5]=

간접적으로 정의된 엔티티 클래스를 사용하여 가장 무거운 포켓몬 세가지를 찾습니다.

In[6]:=
Click for copyable input
EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]]
Out[6]=
In[7]:=
Click for copyable input
EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]]; EntityValue[%, "Generation"]
Out[7]=

간접적으로 정의된 엔티티 클래스를 사용하여 무게가 50Kg에서 100Kg까지의 노란 포켓몬을 찾습니다.

In[8]:=
Click for copyable input
yellowMidweights = EntityList[ Entity["Pokemon", {"PokedexColor" -> "Yellow", "Weight" -> Between[{ Quantity[50, "Kilograms"], Quantity[100, "Kilograms"]}]}]]
Out[8]=

이 포켓몬의 캐릭터의 콜라주를 무게에 따른 크기로 생성합니다.

In[9]:=
Click for copyable input
ImageCollage[ Rule @@@ EntityValue[yellowMidweights, {"Weight", "Image"}], Background -> White]
Out[9]=

오리지널 그룹 (1세대)의 포켓몬과 최신 그룹 (4세대) 포켓몬의 색을 비교합니다.

전체 Wolfram 언어 입력 표시하기
In[10]:=
Click for copyable input
{color1, color6} = Sort[Tally[EntityValue[EntityList[ Entity["Pokemon", {"Generation" -> Entity["PokemonGeneration", #]}]], "PokedexColor"]]] & /@ {"GenerationI", "GenerationVI"};
In[11]:=
Click for copyable input
PieChart3D[{color1[[All, 2]], color6[[All, 2]]}, PlotLabel -> "Gen. I (outer) vs. Gen. VI (inner)", ChartElementFunction -> "ProfileSector3D", SectorOrigin -> {Automatic, 1}, ChartStyle -> (color1[[All, 1]] /. co_Entity :> Symbol[co[[2]]]), ChartLegends -> color1[[All, 1]]]
Out[11]=

관련 예제

de en es fr ja pt-br ru zh