Wolfram Language™

Satzstrukturen vergleichen

Die Struktur von zwei Sätzen kann durch die Berechnung und Verarbeitung ihrer jeweiligen Satzkomponenten verglichen werden.

Veranschaulichen Sie die Struktur eines Satzes als Baumgraph.

In[1]:=

graph = TextStructure["Time flies like an arrow.", "ConstituentGraph"]

Out[1]=

Berechnen Sie die Matrix der Distanzen zwischen allen Knoten des Graphen.

In[2]:=

distancemat1 = GraphDistanceMatrix[First[graph]]; MatrixForm[distancemat1]

Out[2]//MatrixForm=

Gehen Sie auf ähnliche Weise mit einem anderen Satz vor.

In[3]:=

graph2 = TextStructure["I fly in the sky.", "ConstituentGraph"]; distancemat2 = GraphDistanceMatrix[First[graph2]];

Vergleichen Sie die Struktur der zwei Sätze, indem Sie ihre Distanzmatritzen gegenüberstellen.

In[4]:=

distancemat1 == distancemat2

Out[4]=

Die beiden Sätze haben dieselbe Struktur.

Finden Sie Sätze mit identischer Struktur in zwei unterschiedlichen Wikipedia-Artikeln. Extrahieren Sie zuerst Sätze mit einer bestimmten Wortanzahl und erstellen Sie Graphen für beide.

In[5]:=

processWikiPage[article_] := Select[TextCases[WikipediaData[article], "Sentences"], WordCount[#] < 5 &]; genStructure[article_] := Flatten[TextStructure[#, "ConstituentGraph"] & /@ processWikiPage[article]];

In[6]:=

phrasestruct1 = genStructure["Philosophy"]; phrasestruct2 = genStructure["History"];

Berechnen Sie die Distanzmatritzen.

In[7]:=

adj1 = GraphDistanceMatrix /@ phrasestruct1; adj2 = GraphDistanceMatrix /@ phrasestruct2;

Vergleichen Sie die Sätze der beiden Artikel paarweise.

In[8]:=

comparison = Outer[Equal, adj1, adj2, 1];

Dies sind die Satzpaare mit identischer Struktur.

In[9]:=

pickedSentences = Flatten[Pick[Outer[List, phrasestruct1, phrasestruct2], comparison, True], 1];

Dies ist das erste Paar.

In[10]:=

First[pickedSentences]

Out[10]=