使用史密斯分解分析晶格
考虑通过向量 和
的整数倍产生的晶格
.
In[1]:=
![Click for copyable input](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/In_91.png)
b1 = {3, -3};
b2 = {2, 1};
In[2]:=
![Click for copyable input](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/In_92.png)
ptsb = Flatten[Table[j b1 + k b2, {j, -12, 12}, {k, -12, 12}], 1];
In[3]:=
![Click for copyable input](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/In_93.png)
graphicsb =
Graphics[{Blue, PointSize[Large], Point@ptsb}, PlotRange -> 10,
Axes -> True]
Out[3]=
![](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/O_81.png)
以 作为矩阵,其中行为
和
.
In[4]:=
![Click for copyable input](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/In_94.png)
m = {b1, b2};
史密斯分解给出三个满足恒等式 的矩阵.
In[5]:=
![Click for copyable input](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/In_95.png)
{u, r, v} = SmithDecomposition[m];
In[6]:=
![Click for copyable input](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/In_96.png)
u.m.v == r
Out[6]=
![](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/O_82.png)
矩阵 和
的项为整数,行列式为 1.
In[7]:=
![Click for copyable input](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/In_97.png)
{u // MatrixForm, v // MatrixForm, Det[u], Det[v]}
Out[7]=
![](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/O_83.png)
矩阵 为整数矩阵且为对角矩阵. 从其项来看,可以发现
群的结构为
,或直接写为
,因为
是平凡群.
In[8]:=
![Click for copyable input](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/In_98.png)
r // MatrixForm
Out[8]//MatrixForm=
![](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/O_84.png)
恒等式 的右边乘以
,得出
. 由于
是整数矩阵且其行列式为
,
生成的是与
相同的晶格但更简单.
In[9]:=
![Click for copyable input](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/In_99.png)
g = r.Inverse[v];
g // MatrixForm
Out[9]//MatrixForm=
![](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/O_85.png)
可视化由 行生成的晶格.
In[10]:=
![Click for copyable input](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/In_100.png)
ptsg = Flatten[
Table[j First[g] + k Last[g], {j, -12, 12}, {k, -12, 12}], 1];
In[11]:=
![Click for copyable input](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/In_101.png)
graphicsg =
Graphics[{Red, PointSize[Medium], Point@ptsg}, PlotRange -> 10,
Axes -> True]
Out[11]=
![](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/O_86.png)
将新晶格与原来的晶格叠加确认它们是相同的.
In[12]:=
![Click for copyable input](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/In_102.png)
Show[{graphicsb, graphicsg}]
Out[12]=
![](assets.zh/use-the-smith-decomposition-to-analyze-a-lattice/O_87.png)