Wolfram Language

Computação geográfica

Quanto isso pesa?

O peso de um objeto num campo gravitacional é o produto da sua massa e o valor do campo gravitacional no ponto do objeto. Na superfície da Terra, o campo gravitacional não é constante, assim, o mesmo objeto tem pesos diferentes em diferentes localizações. Este exemplo explora a variação da magnitude do campo gravitacional com elevação e latitude.

GeogravityModelData calcula várias propriedades do campo gravitacional da Terra em um determinada localização.

In[1]:=
Click for copyable input
GeogravityModelData[GeoPosition[{0, 0}]]
Out[1]=

Este usa elevação topográfica fornecida por GeoElevationData.

In[2]:=
Click for copyable input
GeoElevationData[GeoPosition[{0, 0}]]
Out[2]=

Ignorando outros efeitos, o campo gravitacional é geralmente menor para uma localização com latitude semelhante, mas elevação maior.

In[3]:=
Click for copyable input
GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]]
Out[3]=
In[4]:=
Click for copyable input
GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]]; {GeoElevationData[%, UnitSystem -> "Metric"], GeogravityModelData[%, "Magnitude"]}
Out[4]=

Calcule a magnitude dos valores do campo gravitacional em pontos equidistantes na linha do equador.

In[5]:=
Click for copyable input
equatorialgravity = GeogravityModelData[{GeoPosition[{0, -180}], GeoPosition[{5, 180}]}, "Magnitude"][[1]]
Out[5]=
In[6]:=
Click for copyable input
ListPlot[equatorialgravity, Joined -> True]
Out[6]=

No histograma a seguir, existem dois picos principais, correspondentes às áreas na terra e ao fundo dos oceanos.

In[7]:=
Click for copyable input
Histogram[equatorialgravity, 20]
Out[7]=

Sobreponha a magnitude do campo gravitacional sobre um mapa de relevo da Terra.

In[8]:=
Click for copyable input
equatorialgravityplot = ListPlot[equatorialgravity, Axes -> False, Joined -> True, AspectRatio -> 1/8, PlotRangePadding -> None, ImagePadding -> None, ImageSize -> 400, PlotStyle -> Red];
In[9]:=
Click for copyable input
worldmap = GeoGraphics[GeoPath["Equator"], GeoRange -> "World", ImageSize -> 400, GeoBackground -> "ReliefMap"];
In[10]:=
Click for copyable input
Overlay[{worldmap, equatorialgravityplot}, Alignment -> Center]
Out[10]=

Para mostrar a variação com a latitude, nós calculamos a média do campo de gravidade pela longitude, e representamos o resultado em relação a latitude.

In[11]:=
Click for copyable input
gravity = Mean /@ GeogravityModelData[{GeoPosition[{-90, -180}], GeoPosition[{90, 180}]}, "Magnitude"];

A Antártida tem um efeito óbvio para latitudes baixas, devido à elevação aumentada.

In[12]:=
Click for copyable input
ListPlot[gravity, DataRange -> {-90, 90}]
Out[12]=
In[13]:=
Click for copyable input
MinMax[gravity]
Out[13]=

Por isso, podem acontecer alterações da ordem de 0,5% no peso de um dado objeto, dependendo de onde é feita a medição.

In[14]:=
Click for copyable input
MinMax[gravity]; 1 - First[%]/Last[%]

Exemplos Relacionados

de en es fr ja ko ru zh