Wolfram Language™

O Marciano

Calcule, represente e meça uma estimativa do caminho seguido por Mark Watney no livro "O Marciano", quando ele viajou de Ares 3 HAB até Ares 4 MAV.

Todas as posições neste exemplo referem-se a posições em Marte. Isso pode ser especificado explicitamente na GeoPosition, ou depois na opção GeoModel.

Estas são estimativas das posições dos desembarques em Ares 3 e 4 .

In[1]:=

ares3 = GeoPosition[{31.2, -28.5}, "Mars"]; ares4 = GeoPosition[{-4.32, 15.28}, "Mars"];

Portanto, esta é a primeira aproximação da viagem de Mark em Marte.

In[2]:=

GeoGraphics[{Orange, Thick, Arrow@GeoPath[{ares3, ares4}]}, GeoRange -> All, GeoProjection -> "Orthographic", Background -> Black]

Out[2]=

De Ares 3 HAB, Mark vai para Marth Vallis, um vale formado por água que ele segue.

In[3]:=

mawrthVallis = GeoPosition[CompressedData[" 1:eJxTTMoPSmViYGCQAGIQLd/6OnCHnJXDN42Y/kOlxgdsua4vLvhr6QAkbbnE jQ8wgMABS4d17g+rRNYZHZg1EwgiLaHqjQ5wgRVaOhz+ChRwMoKqt3BYAhS9 rmx0AKTLPdHCoRBksIHRgf5DQIX8Fg4iIANDjA5oAo35usLcAaLO6EDQDjmg ixD8s2eAgMccrj4NBJ6Zwc0DK99h5vAmEMQyPACmV5s5gN3RYAixf6GZA8Re wwNgdzbB5A0OGINAsZkDxB8GEPf5m0H8H64P9Z8ZxH+H9CDqN5tC/at3AOIu U0h4fNWF2Kdo6uABYhzXhaj/bAL1jy5E/RUTB3A4ztQ5AAD2PaQO "]];

In[4]:=

GeoGraphics[{Thick, Orange, Arrow@GeoPath[mawrthVallis]}, GeoModel -> "Mars", GeoRangePadding -> Quantity[100, "Miles"]]

Out[4]=

Depois Mark passa entre as crateras Trouvelot e Rutherford.

In[5]:=

GeoPosition /@ {Entity["SolarSystemFeature", "TrouvelotMars"], Entity["SolarSystemFeature", "RutherfordMars"]}

Out[5]=

In[6]:=

rtCraters = GeoPosition[{17.52, -11.91}, "Mars"];

E então ele viaja até a cratera Marth.

In[7]:=

marthCrater = GeoPosition[Entity["SolarSystemFeature", "MarthMars"]]

Out[7]=

De lá ele viaja 540 kilometros para o sul.

In[8]:=

pos540S = GeoDestination[marthCrater, GeoDisplacement[{Quantity[540, "Kilometers"], "South"}]]

Out[8]=

E finalmente ele chega perto da cratera Schiaparelli.

In[9]:=

schiaparelliCrater = GeoPosition[{-0.16, 14.38}, "Mars"]

Out[9]=

In[10]:=

geopath = GeoPath[{{ares3, mawrthVallis[[1, 1]]}, mawrthVallis, {mawrthVallis[[1, -1]], rtCraters, marthCrater, pos540S, schiaparelliCrater, ares4}}];

Este caminho geográfico tem a seguinte distância na superfície de Marte.

In[11]:=

GeoLength[geopath, GeoModel -> "Mars"]

Out[11]=

Finalmente, adicione o número de lugares mencionados no livro, com as respectivas identificações.

In[12]:=

labeled[pos_, label_, offset_: {Left, Bottom}] := {Point[pos], Text[Style[label, Directive[12, Italic, White]], pos, offset]}

In[13]:=

points = labeled @@@ Join[EntityValue[{Entity["SolarSystemFeature", "ArabiaTerraMars"], Entity["DeepSpaceProbe", "MarsPathfinder"], Entity["DeepSpaceProbe", "MERDashBOpportunityRover"], Entity["SolarSystemFeature", "TerraMeridianiMars"], Entity["SolarSystemFeature", "RutherfordMars"], Entity["SolarSystemFeature", "BecquerelMars"], Entity["SolarSystemFeature", "TrouvelotMars"], Entity["SolarSystemFeature", "MarthMars"]}, {"Position", "Name"}], { {ares3, "Ares 3 HAB"}, {ares4, "Ares 4 MAV", {Right, Bottom}}}];

Este é o mapa final da viagem.

In[14]:=

GeoGraphics[{Orange, Thick, geopath, PointSize[Large], points}, GeoModel -> "Mars"]

Out[14]=