Der Marsianer: Neu in Wolfram Language 11

Der Marsianer

Berechnen, repräsentieren und messen Sie die geschätzte Strecke, die Mark Watney im Buch "Der Marsianer" auf seinem Weg von der Ares 3 HAB zur Ares 4 MAV zurückgelegt hat.

Alle Positionen in diesem Beispiel beziehen sich auf Positionen auf dem Mars. Dies kann entweder explizit in GeoPosition oder später durch die GeoModel-Option bestimmt werden.

Dies sind die geschätzten Landepositionen von Ares 3 und 4.

In[1]:=

ares3 = GeoPosition[{31.2, -28.5}, "Mars"];
ares4 = GeoPosition[{-4.32, 15.28}, "Mars"];

Somit ist das die erste Approximation von Mark Watneys Trip auf dem Mars.

In[2]:=

GeoGraphics[{Orange, Thick, Arrow@GeoPath[{ares3, ares4}]}, 
 GeoRange -> All, GeoProjection -> "Orthographic", 
 Background -> Black]

Out[2]=

Von der Ares 3 HAB bewegt sich Mark zum Marth Vallis, einem vom Wasser geschaffenen Tal, dessen Verlauf er folgt.

In[3]:=

mawrthVallis = GeoPosition[CompressedData["
1:eJxTTMoPSmViYGCQAGIQLd/6OnCHnJXDN42Y/kOlxgdsua4vLvhr6QAkbbnE
jQ8wgMABS4d17g+rRNYZHZg1EwgiLaHqjQ5wgRVaOhz+ChRwMoKqt3BYAhS9
rmx0AKTLPdHCoRBksIHRgf5DQIX8Fg4iIANDjA5oAo35usLcAaLO6EDQDjmg
ixD8s2eAgMccrj4NBJ6Zwc0DK99h5vAmEMQyPACmV5s5gN3RYAixf6GZA8Re
wwNgdzbB5A0OGINAsZkDxB8GEPf5m0H8H64P9Z8ZxH+H9CDqN5tC/at3AOIu
U0h4fNWF2Kdo6uABYhzXhaj/bAL1jy5E/RUTB3A4ztQ5AAD2PaQO
"]];

In[4]:=

GeoGraphics[{Thick, Orange, Arrow@GeoPath[mawrthVallis]}, 
 GeoModel -> "Mars", GeoRangePadding -> Quantity[100, "Miles"]]

Out[4]=

Dann geht Mark zwischen dem Trouvelot-Krater und dem Rutherford-Krater durch.

In[5]:=

GeoPosition /@ {Entity["SolarSystemFeature", "TrouvelotMars"], 
  Entity["SolarSystemFeature", "RutherfordMars"]}

Out[5]=

In[6]:=

rtCraters = GeoPosition[{17.52, -11.91}, "Mars"];

Anschließend setzt er seinen Weg zum Marth-Krater fort.

In[7]:=

marthCrater = GeoPosition[Entity["SolarSystemFeature", "MarthMars"]]

Out[7]=

Von dort marschiert er 540 km in südliche Richtung.

In[8]:=

pos540S = 
 GeoDestination[marthCrater, 
  GeoDisplacement[{Quantity[540, "Kilometers"], "South"}]]

Out[8]=

Schließlich nähert er sich dem Schiaparelli-Krater.

In[9]:=

schiaparelliCrater = GeoPosition[{-0.16, 14.38}, "Mars"]

Out[9]=

In[10]:=

geopath = 
  GeoPath[{{ares3, mawrthVallis[[1, 1]]}, 
    mawrthVallis, {mawrthVallis[[1, -1]], rtCraters, marthCrater, 
     pos540S, schiaparelliCrater, ares4}}];

Diese Strecke hat auf der Marsoberfläche die folgende Länge:

In[11]:=

GeoLength[geopath, GeoModel -> "Mars"]

Out[11]=

Markieren Sie auf der Karte anschließend einige im Buch erwähnte Orte mit der entsprechenden Beschriftung.

In[12]:=

labeled[pos_, label_, offset_: {Left, Bottom}] := {Point[pos], 
  Text[Style[label, Directive[12, Italic, White]], pos, offset]}

In[13]:=

points = labeled @@@ 
   Join[EntityValue[{Entity["SolarSystemFeature", "ArabiaTerraMars"], 
      Entity["DeepSpaceProbe", "MarsPathfinder"], 
      Entity["DeepSpaceProbe", "MERDashBOpportunityRover"], 
      Entity["SolarSystemFeature", "TerraMeridianiMars"], 
      Entity["SolarSystemFeature", "RutherfordMars"], 
      Entity["SolarSystemFeature", "BecquerelMars"], 
      Entity["SolarSystemFeature", "TrouvelotMars"], 
      Entity["SolarSystemFeature", "MarthMars"]}, {"Position", 
      "Name"}], {
     {ares3, "Ares 3 HAB"}, {ares4, "Ares 4 MAV", {Right, Bottom}}}];

Das ist die Karte der gesamten Route.

In[14]:=

GeoGraphics[{Orange, Thick, geopath, PointSize[Large], points}, 
 GeoModel -> "Mars"]

Out[14]=

Wolfram Language™

Der Marsianer

Verwandte Beispiele