Route durch alle Hauptstädte der zusammenhängenden US-Staaten
Ermitteln Sie die Liste der Hauptstädte der 48 zusammenhängenden US-Staaten.
In[1]:=
capitals =
EntityValue[
EntityClass["AdministrativeDivision", "ContinentalUSStates"],
"CapitalCity"]
Out[1]=
Downloaden Sie die jeweiligen GeoPosition-Koordinaten.
In[2]:=
GeoPosition[capitals]
Out[2]=
Berechnen Sie die Reihenfolge, in der die Städte besucht werden sollen, um die geodätische Gesamtdistanz zu minimieren.
In[3]:=
GeoPosition[capitals];
{d, perm} = FindShortestTour[%]
Out[3]=
Stellen Sie diesen Pfad auf einer Karte dar.
In[4]:=
GeoGraphics[{GeoPath[capitals[[perm]]], Red, PointSize[Medium],
Point[capitals]}]
Out[4]=
Berechnen Sie nun die entsprechende Fahrtroute, um in dieser Reihenfolge durch diese Städte zu fahren.
In[5]:=
td = TravelDirections[capitals[[perm]]];
Stellen Sie den resultierenden Pfad auf einer Karte dar.
In[6]:=
GeoGraphics[{td["TravelPath"], Red, PointSize[Medium],
Point[capitals]}]
Out[6]=
Die zurückzulegende Gesamtdistanz ist:
In[7]:=
td["TravelDistance"]
Out[7]=
Vergleichen Sie diese mit der geodätischen Entfernung.
In[8]:=
d
Out[8]=