Wolfram Language™

Wie schwer ist es?

Das Gewicht eines Objekts in einem Gravitationsfeld ist das Produkt seiner Masse und der herrschenden Gravitationskraft. Auf der Erdoberfläche ist die Gravitationskraft nicht konstant, daher ist dasselbe Objekt an unterschiedlichen Orten unterschiedlich schwer. Dieses Beispiel befasst sich mit den durch Höhe und Breitengrad bedingten Schwankungen der Gravitationsfeldstärke.

GeogravityModelData berechnet Eigenschaften des Gravitationsfelds der Erde an einem bestimmten Ort.

In[1]:=

GeogravityModelData[GeoPosition[{0, 0}]]

Out[1]=

Die dazu verwendeten topographischen Höhendaten stammen von GeoElevationData.

In[2]:=

GeoElevationData[GeoPosition[{0, 0}]]

Out[2]=

Lässt man andere Faktoren beiseite, ist das Gravitationsfeld an einem Ort mit ähnlichem Breitengrad, der aber höher gelegen ist, normalerweise kleiner.

In[3]:=

GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]]

Out[3]=

In[4]:=

GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]]; {GeoElevationData[%, UnitSystem -> "Metric"], GeogravityModelData[%, "Magnitude"]}

Out[4]=

Berechnen Sie die Gravitationsfeldstärke an äquidistanten Punkten am Äquator.

In[5]:=

equatorialgravity = GeogravityModelData[{GeoPosition[{0, -180}], GeoPosition[{5, 180}]}, "Magnitude"][[1]]

Out[5]=

In[6]:=

ListPlot[equatorialgravity, Joined -> True]

Out[6]=

Das Diagramm zeigt zwei ausgeprägte Spitzen, die der Landmasse und dem Boden der Ozeane entsprechen.

In[7]:=

Histogram[equatorialgravity, 20]

Out[7]=

Legen Sie die Größenvisualisierung des Gravitationsfeldes über eine Reliefkarte der Erde.

In[8]:=

equatorialgravityplot = ListPlot[equatorialgravity, Axes -> False, Joined -> True, AspectRatio -> 1/8, PlotRangePadding -> None, ImagePadding -> None, ImageSize -> 400, PlotStyle -> Red];

In[9]:=

worldmap = GeoGraphics[GeoPath["Equator"], GeoRange -> "World", ImageSize -> 400, GeoBackground -> "ReliefMap"];

In[10]:=

Overlay[{worldmap, equatorialgravityplot}, Alignment -> Center]

Out[10]=

Um die Stärkenschwankung des Gravitationsfeldes je nach Breitengrad zu verdeutlichen, nehmen wir den jeweiligen Durchschnittswert der Gravitationsfeldstärke der Längengrade und stellen das Ergebnis in Bezug auf Breitengrade dar.

In[11]:=

gravity = Mean /@ GeogravityModelData[{GeoPosition[{-90, -180}], GeoPosition[{90, 180}]}, "Magnitude"];

Die Antarktis hat aufgrund der zusätzlichen Höhe bei niedrigen Breitengraden eine offensichtliche Wirkung.

In[12]:=

ListPlot[gravity, DataRange -> {-90, 90}]

Out[12]=

In[13]:=

MinMax[gravity]

Out[13]=

Daher kann das Gewicht eines beliebigen Objekts um 0,5 % schwanken, je nachdem, wo es gemessen wird.

In[14]:=

MinMax[gravity]; 1 - First[%]/Last[%]