Wolfram Language

Medidas em probabilidade e estatística

Trabalhando com séries temporais cujos valores são medidas estatísticas

Analise a variabilidade de temperatura em um determinado local.

In[1]:=
Click for copyable input
data = WeatherData[ Entity["City", {"Champaign", "Illinois", "UnitedStates"}], "Temperature", {{2016, 3, 20}, {2016, 3, 22}}];
In[2]:=
Click for copyable input
temps = TimeSeries[data, MissingDataMethod -> "Interpolation"]
Out[2]=

Visualize a séries temporais de temperatura.

In[3]:=
Click for copyable input
DateListPlot[temps, PlotTheme -> "Detailed"]
Out[3]=

Propriedades básicas.

In[4]:=
Click for copyable input
stats = {Min, Max, Mean, Median, StandardDeviation}; TableForm[{Map[#[temps] &, stats]}, TableHeadings -> {None, stats}]
Out[4]//TableForm=

Converta as temperaturas em graus Fahrenheit.

In[5]:=
Click for copyable input
tempsF = UnitConvert[temps, "DegreesFahrenheit"]; TableForm[{Map[#[tempsF] &, stats]}, TableHeadings -> {None, stats}]
Out[5]//TableForm=

Ache a média móvel de 6 horas.

In[6]:=
Click for copyable input
avg = MovingMap[Mean, temps, {Quantity[6, "Hours"], Center}]
Out[6]=
mostre o input completo da Wolfram Language
In[7]:=
Click for copyable input
DateListPlot[{temps, avg}, PlotLegends -> {"temperatures", "6-hour moving average"}, FrameLabel -> Automatic, PlotTheme -> "Detailed"]
Out[7]=

Exemplos Relacionados

de en es fr ja ko ru zh