Wolfram Language™

Prepare aspirina

La aspirina es el medicamento más utilizado para tratar el dolor, la fiebre y la inflamación. Esta puede ser sintetizada combinando cantidades equimolares de ácido salicílico y anhídrido acético. Aquí, los datos químicos de Wolfram Knowledgebase son utilizados junto con el marco de cantidades y grupos de entidades, copias e instancias, para estudiar la preparación química de la aspirina.

Represente un lote típico de laboratorio para la preparación de 100 milimolar de aspirina usando EntityGroup.

In[1]:=

reactants = EntityGroup[{EntityInstance[Entity["Chemical", "SalicylicAcid"], Quantity[0.1, "Moles"]], EntityInstance[Entity["Chemical", "AceticAnhydride"], Quantity[0.1, "Moles"]]}]

Out[1]=

Calcule el total de masa para este lote usando una forma "currificada" de una consulta de entidades y propiedades.

In[2]:=

mass = reactants["AbsoluteMass"]

Out[2]=

Debido a que el anhídrido acético es un líquido, sería conveniente saber exactamente cuánto se necesita.

In[3]:=

UnitConvert[ EntityInstance[Entity["Chemical", "AceticAnhydride"], Quantity[0.1, "Moles"]]["AbsoluteVolume"], "Milliliter"]

Out[3]=

Suponiendo un estequiométrico, ej. una reacción cuantitativa (teórica), esto produce 100 milimoles de aspirina. Sin embargo, en la práctica produce alrededor del 90%.

In[4]:=

EntityInstance[Entity["Chemical", "Aspirin"], 0.9*Quantity[0.1, "Moles"]]["AbsoluteMass"]

Out[4]=

Cuente los átomos que constituyen la molécula de aspirina.

In[5]:=

elem = Entity["Chemical", "Aspirin"]["ElementCounts"]

Out[5]=

Reúna los números adecuados de estos átomos en una expresión de entidades agrupadas.

In[6]:=

atomAssemble = EntityGroup[ MapThread[EntityCopies[#1, #2] &, {Keys[elem], Values[elem]}]]

Out[6]=

In[7]:=

atomicmass = atomAssemble["AtomicMass"]

Out[7]=

Como se espera, la masa atómica total de este grupo de entidades coincide con la masa molar de la molécula completa.

In[8]:=

molarmass = Entity["Chemical", "Aspirin"][ EntityProperty["Chemical", "MolarMass"]]

Out[8]=

In[9]:=

Equal @@ QuantityMagnitude /@ {atomicmass, molarmass}

Out[9]=

Sin embargo, existen otras combinaciones isotópicas posibles, cada una de ellas con una masa total ligeramente diferente.

In[10]:=

stableIsotopes = #[EntityProperty["Element", "StableIsotopes"]] & /@ Keys[elem]

Out[10]=

Este grupo consiste solamente de isótopos estándar (el llamado "de iones principales").

In[11]:=

EntityGroup[{EntityCopies[Entity["Isotope", "C12"], 9], EntityCopies[Entity["Isotope", "H1"], 8], EntityCopies[Entity["Isotope", "O16"], 4]}]["AtomicMass"]

Out[11]=

La probabilidad de ocurrencia de una molécula con tal composición es menor al 90%. Sin embargo, en un espectro de masas sería el pico molecular más prominente.

In[12]:=

Times @@ MapThread[(QuantityMagnitude[#1[ EntityProperty["Isotope", "IsotopeAbundance"]], "PureUnities"])^#2 &, {stableIsotopes[[All, 1]], Values[elem]}]

Out[12]=