規則的にサンプルされたオルンシュタイン・ウーレンベック過程を自己回帰過程として同定する 

Mathematica 10では過程のスライスの計算のサポートが向上しているため，多変量過程のスライスにモーメント法をそのまま使って2つの過程間で等価法則が設定できる．

自己回帰(AR)過程とオルンシュタイン・ウーレンベック(OU)過程はともにガウス過程であり，平均および分散の関数により判定される．

In[1]:=

X ar\[ScriptCapitalP] = ARProcess[c, {a1}, si2]; ou\[ScriptCapitalP] = OrnsteinUhlenbeckProcess[mu, si, th];

スライス分布にモーメント法を使い，等間隔時間格子で定常AR過程のパラメータを定常OU過程の制約にマッチさせる．

In[2]:=

X arSlice\[ScriptCapitalD] = ar\[ScriptCapitalP][{0, 1, 2, 3, 4}]; ouSlice\[ScriptCapitalD] = ou\[ScriptCapitalP][{dt, 2 dt, 3 dt, 4 dt, 5 dt}];

In[3]:=

X {sol1} = (Solve[{Mean[arSlice\[ScriptCapitalD]] == Mean[ouSlice\[ScriptCapitalD]], Covariance[arSlice\[ScriptCapitalD]] == Covariance[ouSlice\[ScriptCapitalD]]}, {c, a1, si2}] // FullSimplify)

Out[3]=

共分散関数が記号的遅れに一致していることを確認する．

In[4]:=

X Simplify[CovarianceFunction[ar\[ScriptCapitalP] /. sol1, h], dt > 0 && th > 0 && h \[Element] Integers]

Out[4]=

In[5]:=

X CovarianceFunction[ou\[ScriptCapitalP], h dt]

Out[5]=

初期条件付きのAR過程とOU過程の練習を繰り返す．

In[6]:=

X ar\[ScriptCapitalP]2 = ARProcess[c, {a1}, si2, {x0ar}]; ou\[ScriptCapitalP]2 = OrnsteinUhlenbeckProcess[mu, si, th, x0];

In[7]:=

X arSlice\[ScriptCapitalD]2 = ar\[ScriptCapitalP]2[{0, 1, 2, 3, 4}]; ouSlice\[ScriptCapitalD]2 = ou\[ScriptCapitalP]2[{dt, 2 dt, 3 dt, 4 dt, 5 dt}];

In[8]:=

X {sol2} = (Solve[{Mean[arSlice\[ScriptCapitalD]2] == Mean[ouSlice\[ScriptCapitalD]2], Covariance[arSlice\[ScriptCapitalD]2] == Covariance[ouSlice\[ScriptCapitalD]2]}, {c, a1, si2, x0ar}] // FullSimplify)

Out[8]=

自己回帰表現を使って，等間隔時間格子上でオルンシュタイン・ウーレンベックをサンプルする．

In[9]:=

X RandomFunction[ ar\[ScriptCapitalP]2 /. sol2 /. {mu -> 1, si -> 2, th -> 2/3, x0 -> 10, dt -> 0.01}, {0, 200}, 5] // ListPlot[#, ImageSize -> 400] &

Out[9]=