向量联合模型与单变量分量模型 

获取伊利诺伊州香槟市2014年5月的每小时气温记录.

In[1]:=

X start = {2014, 5, 1, 0, 0, 0}; end = {2014, 5, 31, 23, 59, 0};

In[2]:=

X temp = WeatherData[{"Champaign", "IL"}, "Temperature", {start, end}]; temp1 = TimeSeries[temp, MissingDataMethod -> "Interpolation"]; temp2 = TimeSeriesResample[temp1, "Hour"];

用 TimeSeriesAggregate 计算每日最低和最高气温.

In[3]:=

X min = TimeSeriesAggregate[temp2, "Day", Min]; max = TimeSeriesAggregate[temp2, "Day", Max];

将其合并到向量时间序列中.

In[4]:=

X dataAll = TimeSeries[TimeSeriesThread[QuantityMagnitude, {min, max}], MetaInformation -> {"Units" -> {"DegreesCelsius", "DegreesCelsius"}, "Observation" -> {"Min Temperature", "Max Temperature"}}]

Out[4]=

显示完整的 Wolfram 语言输入隐藏输入

In[5]:=

X Table[DateListPlot[dataAll["PathComponent", i], FrameLabel -> {None, dataAll["Units"][[i]]}, PlotLabel -> dataAll["Observation"][[i]], ImageSize -> 250, PlotTheme -> "Detailed"], {i, 2}]

Out[5]=

数据的开始部分会被用于查找模型，数据的剩余部分会作为预测的参考集合.

In[6]:=

X data = TimeSeriesWindow[ dataAll, {Automatic, {2014, 5, 26, 23, 59, 0}}];

气温是互相关的.

In[7]:=

X ListPlot[TimeSeriesMap[Part[#, 1, 2] &, CorrelationFunction[data, {20}]], Filling -> Axis]

Out[7]=

对数据拟合向量模型.

In[8]:=

X model[p_, q_] := ARIMAProcess[p, q]; eproc = EstimatedProcess[data, model[1, 0]]

Out[8]=

对未来5天进行预测.

In[9]:=

X n = 5; forecast = TimeSeriesForecast[eproc, data, {n}, Method -> "Covariance"];

显示完整的 Wolfram 语言输入隐藏输入

In[10]:=

X Table[DateListPlot[{dataAll["PathComponent", i], forecast["PathComponent", i]}, FrameLabel -> {None, data["Units"][[i]]}, PlotLabel -> data["Observation"][[i]], ImageSize -> 250, PlotRange -> All, PlotTheme -> "Detailed"], {i, 2}]

Out[10]=

分别找出两个气温的相同类型但阶数更长的单变量模型.

In[11]:=

X minProc = EstimatedProcess[data["PathComponent", 1], model[3, 0]] minForecast = TimeSeriesForecast[minProc, data["PathComponent", 1], {n}, Method -> "Covariance"];

Out[11]=

In[12]:=

X maxProc = EstimatedProcess[data["PathComponent", 2], model[3, 0]] maxForecast = TimeSeriesForecast[maxProc, data["PathComponent", 2], {n}, Method -> "Covariance"];

Out[12]=

绘制组合的单变量预测.

In[13]:=

X uForecast = TimeSeries[ Transpose@{minForecast["Values"], maxForecast["Values"]}, {minForecast["Dates"]}]

Out[13]=

对比预测.

In[14]:=

X plotData = TimeSeriesWindow[dataAll, {"May 20, 2014", Automatic}];

显示完整的 Wolfram 语言输入隐藏输入

In[15]:=

X Legended[Row@ Table[DateListPlot[{plotData["PathComponent", i], forecast["PathComponent", i], uForecast["PathComponent", i]}, ImageSize -> 250, PlotTheme -> "Detailed", PlotLabel -> dataAll["Observation"][[i]]], {i, 1, 2}], Placed[SwatchLegend[{RGBColor[0.368417, 0.506779, 0.709798], RGBColor[0.880722, 0.611041, 0.142051], RGBColor[ 0.560181, 0.691569, 0.194885]}, {"data ", "forecast with a vector model", "forecast with an univariate model"}, LegendLayout -> "Row"], Below]]

Out[15]=

绘制向量预测和 95% 置信带.

显示完整的 Wolfram 语言输入隐藏输入

In[16]:=

X nq = Quantile[NormalDistribution[], 0.975]; ubandV = Table[ TimeSeriesThread[{1, nq}.# &, {forecast["PathComponent", i], TimeSeriesMap[Sqrt[#[[i, i]]] &, forecast["MeanSquaredErrors"]]}], {i, 1, 2}]; lbandV = Table[ TimeSeriesThread[{1, -nq}.# &, {forecast["PathComponent", i], TimeSeriesMap[Sqrt[#[[i, i]]] &, forecast["MeanSquaredErrors"]]}], {i, 1, 2}];

In[17]:=

X pV = Table[ DateListPlot[{plotData["PathComponent", i], forecast["PathComponent", i], ubandV[[i]], lbandV[[i]]}, PlotStyle -> {Automatic, RGBColor[0.880722, 0.611041, 0.142051], Brown, Brown}, PlotRange -> All, Filling -> {3 -> {4}, 6 -> {7}}, PlotTheme -> "Detailed", PlotLabel -> dataAll["Observation"][[i]], ImageSize -> 250], {i, 1, 2}]; Legended[Row[pV], Placed[SwatchLegend[{RGBColor[0.368417, 0.506779, 0.709798], RGBColor[0.880722, 0.611041, 0.142051], Brown}, {"data ", "vector forecast"}, LegendLayout -> "Row"], Bottom]]

Out[17]=

绘制单变量预测和 95% 置信带.

显示完整的 Wolfram 语言输入隐藏输入

In[18]:=

X err = {minForecast["MeanSquaredErrors"], maxForecast["MeanSquaredErrors"]};

In[19]:=

X nq = Quantile[NormalDistribution[], 0.975]; ubandU = Table[ TimeSeriesThread[{1, nq}.# &, {uForecast["PathComponent", i], TimeSeriesMap[Sqrt, err[[i]]]}], {i, 1, 2}]; lbandU = Table[ TimeSeriesThread[{1, -nq}.# &, {uForecast["PathComponent", i], TimeSeriesMap[Sqrt, err[[i]]]}], {i, 1, 2}];

In[20]:=

X pU = Table[ DateListPlot[{plotData["PathComponent", i], uForecast["PathComponent", i], ubandU[[i]], lbandU[[i]]}, PlotStyle -> {Automatic, RGBColor[0.560181, 0.691569, 0.194885], Gray, Gray}, PlotRange -> All, Filling -> {3 -> {4}, 6 -> {7}}, PlotTheme -> "Detailed", PlotLabel -> dataAll["Observation"][[i]], ImageSize -> 250], {i, 1, 2}]; Legended[Row[pU], Placed[SwatchLegend[{RGBColor[0.368417, 0.506779, 0.709798], RGBColor[0.560181, 0.691569, 0.194885], Gray}, {"data ", "univariate forecast"}, LegendLayout -> "Row"], Bottom]]

Out[20]=

比较预测和对应的置信带.

显示完整的 Wolfram 语言输入隐藏输入

In[21]:=

X Legended[Grid[{First /@ {pV, pU}, Last /@ {pV, pU}}], Placed[SwatchLegend[{RGBColor[0.368417, 0.506779, 0.709798], RGBColor[0.880722, 0.611041, 0.142051], RGBColor[ 0.560181, 0.691569, 0.194885]}, {"data ", "forecast with a vector model", "forecast with an univariate model"}, LegendLayout -> "Row"], Below]]

Out[21]=