Wolfram Language

Differential Eigensystems

Create a Gallery of Eigenfunctions for the Laplacian in a Ball

Define a 3D Laplacian operator.

In[1]:=
Click for copyable input
\[ScriptCapitalL] = -Laplacian[u[x, y, z], {x, y, z}];

Specify homogeneous Dirichlet boundary conditions.

In[2]:=
Click for copyable input
\[ScriptCapitalB] = DirichletCondition[u[x, y, z] == 0, True];

Find the 16 smallest eigenvalues and eigenfunctions in a ball.

In[3]:=
Click for copyable input
\[CapitalOmega] = Ball[{0, 0, 0}, 2];
In[4]:=
Click for copyable input
{vals, funs} = DEigensystem[{\[ScriptCapitalL], \[ScriptCapitalB]}, u[x, y, z], {x, y, z} \[Element] \[CapitalOmega], 16];

The eigenvalues are given in terms of BesselJZero.

In[5]:=
Click for copyable input
vals[[1]] // TraditionalForm
Out[5]//TraditionalForm=

Generate a gallery of the eigenfunctions.

show complete Wolfram Language input
In[6]:=
Click for copyable input
Grid[Partition[ ParallelTable[ DensityPlot3D[ funs[[i]] // N // Evaluate, {x, y, z} \[Element] \[CapitalOmega], Boxed -> False, Axes -> False, ColorFunction -> Hue, Method -> {"ShrinkWrap" -> True}, ImageSize -> 125], {i, 16}], 4]]
Out[6]=

Related Examples

de es fr ja ko pt-br ru zh