Wolfram Language

Differential Eigensystems

Find AharonovBohm Eigenvalues

The AharonovBohm effect is a quantum mechanical phenomenon where a charged particle detects an electromagnetic gauge potential even though the magnetic field inside the region where the particle can move is zero. In this example, the Schrödinger equation for a fixed magnetic field concentrated at a line perpendicular to the domain of the particle is considered.

Specify the region as sector in the plane centered about the axis.

Click for copyable input
\[CapitalOmega] = Disk[{0, 0}, 1, {-\[Pi]/8, \[Pi]/8}];

Specify the AharonovBohm operator. The magnetic field is restricted to the axis.

Click for copyable input
A = 1/2 {-(y - b), x - a}/((x - a)^2 + (y - b)^2) /. {a -> 0.2, b -> 0.4}; \[ScriptCapitalL] = -Laplacian[u[x, y], {x, y}] + I Div[A, {x, y}] u[x, y] + 2 I A.D[u[x, y], {{x, y}}] + A.A u[x, y];

Specify Dirichlet boundary conditions on the entire boundary.

Click for copyable input
\[ScriptCapitalB] = DirichletCondition[u[x, y] == 0, True];

Compute six eigenvalues and eigenfunctions of the operator.

Click for copyable input
{vals, funs} = NDEigensystem[{\[ScriptCapitalL], \[ScriptCapitalB]}, u[x, y], {x, y} \[Element] \[CapitalOmega], 6];

Inspect the eigenvalues.

Click for copyable input

Visualize the real part of the eigenfunctions.

show complete Wolfram Language input
Click for copyable input
Grid[Partition[ Plot3D[Re[#], {x, y} \[Element] \[CapitalOmega], ColorFunction -> "TemperatureMap", Boxed -> False, Axes -> None, PlotRange -> All, PlotStyle -> {Specularity[White, 20]}, Method -> {"ShrinkWrap" -> True}] & /@ funs, 3], Background -> Transparent] // Quiet

Related Examples

de es fr ja ko pt-br ru zh