Nichtparametrische Verteilungen von Größendaten
Verwenden Sie WeatherData zur Ermittlung von Zeitreihen der Windgeschwindigkeitsmessung in Chicago seit Anfang 2014 bis Ende 2015.
In[1]:=
wsts = WeatherData["Chicago",
"WindSpeed", {DateObject[{2014, 1, 1}], DateObject[{2015, 12, 31}]}]Out[1]=
Visualisieren Sie mit Histogram die Verteilung der Windgeschwindigkeiten.
In[2]:=
Histogram[wsts, PlotTheme -> "Detailed", FrameLabel -> Automatic]Out[2]=
Extrahieren Sie die Werte der Windgeschwindigkeit mit interpolierten fehlenden Werten.
In[3]:=
winds = Values[TimeSeries[wsts, MissingDataMethod -> "Interpolation"]]Out[3]=
Konstruieren Sie mit SmoothKernelDistribution ein nichtparametrisches Modell der Windgeschwindigkeit in Chicago, und vergewissern Sie sich, dass die Windgeschwindigkeitswerte nichtnegativ sind.
In[4]:=
ws\[ScriptCapitalD] =
SmoothKernelDistribution[winds,
Automatic, {"Bounded", Quantity[0, ("Kilometers")/("Hours")],
"Gaussian"}]Out[4]=
Verwenden Sie ein nichtparametrisches Modell der Leistungskraft der Turbine als eine Funktion der Windgeschwindigkeit, um die durchschnittliche Leistung einer GE 1,5 MW-Windturbine zu schätzen.
In[5]:=
turbine =
Interpolation[
QuantityArray[{{0.`, 0.`}, {0.5`, 0.`}, {1.`, 0.`}, {1.5`,
0.`}, {2.`, 0.`}, {2.5`, 0.`}, {3.`, 0.`}, {3.5`, 0.`}, {4.`,
36.`}, {4.5`, 66.`}, {5.`, 104.`}, {5.5`, 150.`}, {6.`,
205.`}, {6.5`, 269.`}, {7.`, 344.`}, {7.5`, 428.`}, {8.`,
528.`}, {8.5`, 644.`}, {9.`, 774.`}, {9.5`, 926.5`}, {10.`,
1079.`}, {10.5`, 1211.`}, {11.`, 1342.`}, {11.5`,
1401.`}, {12.`, 1460.`}, {12.5`, 1477.`}, {13.`,
1494.`}, {13.5`, 1500.`}, {30.`, 1500.`}}, {"Meters"/"Seconds",
"Kilowatts"}] // Normal, InterpolationOrder -> 1];In[6]:=
NExpectation[turbine[v], v \[Distributed] ws\[ScriptCapitalD]]Out[6]=
