Wolfram Language™

Tunnel

TunnelData liefert Informationen zu Tunneln, wie z.B. deren Länge und Standort.

In[1]:=

tunnels = TunnelData[];

In[2]:=

Length[tunnels]

Out[2]=

Ermitteln Sie Länge und Standort jedes Tunnels, je nach gegebenem Land oder Ländern.

In[3]:=

rawData = TunnelData[tunnels, {"Countries", "Length"}];

Bereinigen Sie die Daten, um fehlende Werte zu entfernen.

In[4]:=

data = DeleteMissing[rawData, 1, 2];

Konvertieren Sie die Längedaten in Meilen.

In[5]:=

data[[All, 2]] = UnitConvert[N[data[[All, 2]]], "Miles"];

In[6]:=

lengths = data[[All, 2]];

In[7]:=

MinMax[lengths]

Out[7]=

In[8]:=

h = Histogram[lengths, {1, 12, .5}, PDF, FrameLabel -> Automatic, PlotTheme -> "Detailed"]

Out[8]=

Die Daten können durch eine Mischung aus Long-Tailed-Verteilungen beschrieben werden.

In[9]:=

dist = MixtureDistribution[{w1, w2}, {ParetoDistribution[a1, a2, a3, a4], WeibullDistribution[b1, b2]}];

In[10]:=

edist = EstimatedDistribution[lengths, dist]

Out[10]=

Testen Sie die Güte des Modells in Gegenüberstellung zu parametrischen Mischverteilungen.

In[11]:=

DistributionFitTest[lengths, dist, "TestDataTable"]

Out[11]=

Plotten Sie WDF des angepassten Verteilungsmodells in Gegenüberstellung zum Histogramm.

In[12]:=

Show[h, Plot[PDF[edist, Quantity[x, "Miles"]], {x, 1, 12}, PlotRange -> All] // Quiet]

Out[12]=

Visualisieren Sie den Standort der Tunnel.

Gruppieren Sie die Tunnel nach Land.

In[13]:=

res = GroupBy[data, First, Flatten[Take[#, All, -1]] &];

Manche Tunnel erstrecken sich über mehr als ein Land.

In[14]:=

shared = Select[Keys[res], Length[#] > 1 &]

Out[14]=

Verteilen Sie die Tunnel, die sich mehrere Länder teilen, und wählen Sie jene Länder mit mindestens 10 Tunneln aus. Plotten Sie das Diagramm der Längenverteilung.

In[15]:=

split = GroupBy[ Flatten[Map[{{{#[[1]]}, res[#]}, {{#[[2]]}, res[#]}} &, shared], 1], First, Flatten[#[[All, 2]]] &];

In[16]:=

together = Join[KeyDrop[res, shared], split, 2];

In[17]:=

tc = SortBy[Select[Normal[together], Length[#[[2]]] >= 10 &], Length@*Last];

In[18]:=

DistributionChart[tc[[All, 2]], ChartLabels -> tc[[All, 1, 1]], BarOrigin -> Left, BarSpacing -> .3, FrameLabel -> {"Miles"}, LabelingFunction -> (Placed[Length[#1], After] &), ChartStyle -> "SandyTerrain", ImageSize -> Large]

Out[18]=

Die Gesamttunnelkilometerzahl jedes Landes enthält auch die volle Länge gemeinsamer Tunnel.

In[19]:=

vals = KeyMap[First, Map[Total, together]]; title = Style["tunnel mileage", 24, Bold, GrayLevel[.2], FontFamily -> "Osaka"]; GeoRegionValuePlot[vals, GeoProjection -> "Mercator", GeoRange -> {{-65, 80}, {-170, 190}}, PlotLegends -> Automatic, ColorFunction -> (ColorData["StarryNightColors", 2 #] &), Epilog -> Inset[title, {30, -65}], ImageSize -> 500]

Out[19]=