Wolfram Language™

Weltweite Atomreaktoren

NuclearReactorData liefert Daten zu den bekannten Atomreaktoren auf der ganzen Welt. Manche befinden sich bereits außer Betrieb, so wie Tschernobyl. Für die Analyse der globalen Atomenergie-Ressourcen können Sie die derzeit aktiven Reaktoren auswählen.

In[1]:=

reactors = NuclearReactorData[];

In[2]:=

active = Keys@ Select[EntityValue["NuclearReactor", "Status", "EntityAssociation"], # === "operational" &];

Extrahieren Sie die jährliche Energieproduktion und das Land des Standorts.

In[3]:=

annualproduction = NuclearReactorData[active, "AnnualEnergyProduction"]; countries = Map[First, NuclearReactorData[active, "Countries"]];

Erstellen Sie einen Datensatz und entfernen Sie die Datenpunkte, die fehlende Werte enthalten. Die Zahl der aktiven Reaktoren liegt bei über 400.

In[4]:=

data = Transpose[{active, countries, annualproduction}]; data = DeleteMissing[data, 1, 2];

In[5]:=

data // Dimensions

Out[5]=

Die Reaktoranzahl pro Land.

In[6]:=

percountry = GroupBy[data, #1[[2]] &];

In[7]:=

numberpercountry = Map[Length, percountry];

In[8]:=

BarChart[Sort[numberpercountry], ChartLabels -> Automatic, ChartStyle -> "DarkRainbow", BarOrigin -> Left, BarSpacing -> 1, LabelingFunction -> (Placed[#1, After] &), ImageSize -> Large]

Out[8]=

Die Zahl der Reaktoren entspricht der Gesamtproduktion von Atomenergie pro Land.

In[9]:=

energytotals = Map[Total[#[[All, 3]]] &, percountry];

In[10]:=

stats = {Min, Max, Mean, Median, Total}; TableForm[#[energytotals] & /@ stats, TableHeadings -> {stats}]

Out[10]//TableForm=

Die größten Produzenten von Atomenergie sind die Vereinigten Staaten und Frankreich.

In[11]:=

TakeLargest[energytotals, 2]

Out[11]=

In[12]:=

GeoRegionValuePlot[energytotals, GeoProjection -> "Mercator", GeoRange -> {{-70, 80}, {-170, 190}}, GeoLabels -> (Tooltip[#1, #2] &)]

Out[12]=

Die Weltkarte sind anders aus, wenn man die Pro-Kopf-Gesamtenergieproduktion in betrachtet. Verwenden Sie CountryData, um die Einwohnerzahlen für jedes Land der Liste abzurufen.

In[13]:=

populations = AssociationThread[Keys[energytotals], CountryData[#, "Population"] & /@ Keys[energytotals]];

Berechnen Sie die Atomenergie pro Kopf.

In[14]:=

energypercapita = energytotals/populations;

In[15]:=

TableForm[#[energypercapita] & /@ stats, TableHeadings -> {stats}]

Out[15]//TableForm=

Auf der Karte sehen Sie, dass die USA nicht der größte Pro-Kopf-Atomstromproduzent sind, obwohl sie die meiste Atomenergie in absoluten Zahlen produzieren. Frankreich und Schweden führen die Pro-Kopf-Produktion an.

In[16]:=

TakeLargest[energypercapita, 2]

Out[16]=

In[17]:=

GeoRegionValuePlot[energypercapita, GeoProjection -> "Mercator", GeoRange -> {{-70, 80}, {-170, 190}}, GeoLabels -> (Tooltip[#1, #2] &)]

Out[17]=