Wolfram Language™

Conjuntos circulares (COE, CUE, ...)

Os conjuntos circulares são famílias de matrizes unitárias com distribuições invariantes sob diferentes transformações unitárias. As aplicações típicas estão em mecânica estatística, teoria dos números, análise combinatória, e da física nuclear.

Matrizes de um conjunto circular real (CRE) são ortogonais. »

In[1]:=

cre = RandomVariate[CircularRealMatrixDistribution[5]];

In[2]:=

OrthogonalMatrixQ[cre]

Out[2]=

Matrizes de um conjunto circular unitário (CUE) são unitárias. »

In[3]:=

cue = RandomVariate[CircularUnitaryMatrixDistribution[5]];

In[4]:=

UnitaryMatrixQ[cue]

Out[4]=

Matrizes de um conjunto circular ortogonal (COE) são simétricas e unitárias. »

In[5]:=

coe = RandomVariate[CircularOrthogonalMatrixDistribution[5]];

In[6]:=

SymmetricMatrixQ[coe] && UnitaryMatrixQ[coe]

Out[6]=

Matrizes de um conjunto simplético circular (C'EST) são auto-dual quaterniônicas unitárias. »

In[7]:=

selfdualQuaternionicQ[m_] := With[{\[ScriptCapitalJ] = KroneckerProduct[{{0, -1}, {1, 0}}, IdentityMatrix[Length[m]/2]], mat = SetAccuracy[m, 10]}, Transpose[mat].\[ScriptCapitalJ] == \[ScriptCapitalJ].mat];

In[8]:=

cse = RandomVariate[CircularSymplecticMatrixDistribution[5]];

In[9]:=

UnitaryMatrixQ[cse] && selfdualQuaternionicQ[cse]

Out[9]=

Matrizes de um conjunto circular quaterniônicos (CQE) são simpléticas unitárias. »

In[10]:=

symplecticMatrixQ[mat_] := With[{\[ScriptCapitalJ] = KroneckerProduct[{{0, -1}, {1, 0}}, IdentityMatrix[Length[mat]/2]] }, Conjugate[mat].\[ScriptCapitalJ] == \[ScriptCapitalJ].mat];

In[11]:=

cqe = RandomVariate[CircularQuaternionMatrixDistribution[5]];

In[12]:=

UnitaryMatrixQ[cqe] && symplecticMatrixQ[cqe]

Out[12]=

Valores próprios de matrizes de CUE, COE, e CSE tem unidade de comprimento e são uniformemente distribuídas em uma fase.

In[13]:=

args = Flatten[ Arg[RandomVariate[ MatrixPropertyDistribution[Eigenvalues[x], x \[Distributed] #], 10^4]]] & /@ {CircularUnitaryMatrixDistribution[5], CircularOrthogonalMatrixDistribution[5], CircularSymplecticMatrixDistribution[5]}; Row[MapThread[ Histogram[#1, {-Pi, Pi, Pi/10}, Frame -> None, ChartLegends -> Placed[#2, Above]] &, {args, {Style["Unitary", 15], Style["Orthogonal", 15], Style["Symplectic", 15]}}]]

Out[13]=

Visualize a distribuição conjunta da fase dos valores próprios de uma CUE bidimensional e compare-a com a densidade real.

In[14]:=

evs\[ScriptCapitalD] = MatrixPropertyDistribution[Arg[Eigenvalues[x]], x \[Distributed] CircularUnitaryMatrixDistribution[2]]; \[CurlyPhi]s = RandomSample /@ RandomVariate[evs\[ScriptCapitalD], 10^5];

In[14]:=

Show[ Histogram3D[\[CurlyPhi]s, {-Pi, Pi, 0.25}, PDF, PlotTheme -> "Scientific", ChartStyle -> "AvocadoColors"], Plot3D[1/(8 Pi^2) Abs[Exp[I \[Phi]1] - Exp[I \[Phi]2]]^2, {\[Phi]1, -Pi, Pi}, {\[Phi]2, -Pi, Pi}, PlotStyle -> None, MeshStyle -> Thick], ImageSize -> Medium]

Out[15]=