Distribuição de Marchenko–Pastur

A distribuição de Marchenko–Pastur é a distribuição de limite de valores próprios de matrizes de Wishart como a matriz de dimensão e graus de liberdade ambos tendem ao infinito com relação . Para , a distribuição não tem massa pontual e a função densidade de probabilidade está bem definida.

In[1]:=

PDF[MarchenkoPasturDistribution[1/2], x]

Out[1]=

In[2]:=

Plot[PDF[MarchenkoPasturDistribution[1/2], x], {x, 0, 3}, PlotRange -> All, Exclusions -> None, Filling -> Axis, PlotTheme -> "Detailed", ImageSize -> Medium, PlotLegends -> None]

Out[2]=

Pegue uma amostra de uma distribuição de Wishart com a matriz de escala de identidade e calcule os valores próprios escalados.

In[3]:=

n = 10^4; m = 10^3; eigs = RandomVariate[ MatrixPropertyDistribution[Eigenvalues[x]/n, x \[Distributed] WishartMatrixDistribution[n, IdentityMatrix[m]]]];

Compare o resultado da amostra com a função densidade Marchenko-Pastur.

In[4]:=

Show[Histogram[eigs, {0.05}, "PDF", ImageSize -> Medium, PlotTheme -> "Detailed"], Plot[PDF[MarchenkoPasturDistribution[m/n], x], {x, 0, 1.8}, PlotTheme -> "Detailed", PlotLegends -> None, Exclusions -> None]]

Out[4]=

Para , a matriz de Wishart é singular. Com probabilidade , a distribuição tem uma massa no ponto em .

In[5]:=

m = 500; n = 2 m; CDF[MarchenkoPasturDistribution[n/m], 0]

Out[5]=

Gere uma matriz de Wishart singular com covariância de identidade e calcule os valores próprios escalados.

In[6]:=

matrix = Transpose[#].# &[RandomVariate[NormalDistribution[], {m, n}]]; eigvs = Chop[Eigenvalues[matrix]/m];

Existe uma lacuna na densidade de valores próprios próximos de 0, e a coluna em 0 tem uma grande densidade.

In[7]:=

Histogram[eigvs, {0.05}, PDF, PlotRange -> 1, ChartStyle -> Orange, ImageSize -> Medium]

Out[7]=

Ajuste MarchenkoPasturDistribution aos valore próprios.

In[8]:=

edist = EstimatedDistribution[eigvs, MarchenkoPasturDistribution[\[Lambda], 1]]

Out[8]=

A função de distribuição de da distribuição ajustada mostra uma descontinuidade de salto na origem.

In[9]:=

Show[Histogram[eigvs, {0.05}, CDF, ChartStyle -> Orange], Quiet@Plot[CDF[edist, x], {x, -1.5, 5.75}, Exclusions -> None, PlotStyle -> Thick], ImageSize -> Medium, AxesOrigin -> {-1, 0}, PlotRange -> {{-1.5, 6}, {0, 1}}]

Out[9]=