Verborgene Markov-Prozesse mit diskreten oder stetigen, univariaten der multivariaten Emissionen 

Definieren Sie die Anfangswahrscheinlichkeiten und die bedingten Übergangswahrscheinlichkeiten für die verborgenen Zustände.

In[1]:=

X p0 = {1/2, 1/2}; tm = {{3/4, 1/4}, {2/5, 3/5}};

Definieren Sie verborgene Markov-Prozesse mit kategorialen Emissionen.

In[2]:=

X hmm1 = HiddenMarkovProcess[p0, tm, {{2/3, 1/3}, {0, 1}}];

Definieren Sie verborgene Markov-Prozesse mit allgemeinen diskreten Emissionen.

In[3]:=

X hmm2 = HiddenMarkovProcess[p0, tm, {GeometricDistribution[1/3], NegativeBinomialDistribution[5, 1/4]}];

Definieren Sie verborgene Markov-Prozesse mit stetigen Emissionen.

In[4]:=

X hmm3 = HiddenMarkovProcess[p0, tm, {NormalDistribution[2, 1], StudentTDistribution[-2, 1, 7]}];

Definieren Sie verborgene Markov-Prozesse mit multivariaten Emissionen.

In[5]:=

X hmm4 = HiddenMarkovProcess[p0, tm, {MultivariatePoissonDistribution[2, {5, 6}], NegativeMultinomialDistribution[6, {1/3, 1/4}]}];

In[6]:=

X hmm5 = HiddenMarkovProcess[p0, tm, {BinormalDistribution[{-1, 2}, {1, 1}, 1/2], BinormalDistribution[{2, -1}, {1, 1}, -1/2]}];

Nehmen Sie Stichproben von jedem verborgenen Markov-Prozess.

In[7]:=

X procList = {hmm1, hmm2, hmm3, hmm4, hmm5};

In[8]:=

X pathList = Table[RandomFunction[proc, {0, 100}], {proc, procList}];

Berechnen Sie für den jeweiligen Prozess die Log‐Likelihood eines jeden Pfads.

In[9]:=

X MapThread[LogLikelihood, {N[procList], pathList}]

Out[9]=

Visualisieren Sie Stichproben von Pfaden von Prozessen mit univariaten Emissionen.

Die gesamte Wolfram-Language Eingabe zeigenEingabe verbergen

In[10]:=

X Table[ListPlot[path, PlotTheme -> "Detailed", ImagePadding -> {{20, 5}, {20, 5}}], {path, Take[pathList, 3]}] // Row

Out[10]=

Visualisieren Sie Komponenten von Pfaden von Prozessen mit multivariaten Emissionen.

Die gesamte Wolfram-Language Eingabe zeigenEingabe verbergen

In[11]:=

X labeledPlot[path_, lbl_] := Labeled[Column[ MapIndexed[ ListPlot[#1, PlotTheme -> "Detailed", ImagePadding -> {{20, 5}, {20, 5}}, PlotStyle -> ColorData[112][First[#2]]] &, path["PathComponents"]]], lbl]

In[12]:=

X Legended[MapThread[ labeledPlot, {Take[pathList, -2], {"Bivariate discrete", "Bivariate continuous"}}] // Row, SwatchLegend[ ColorData[112, "ColorList"], {"X-component", "Y-component"}]]

Out[12]=