离散或连续、单变量或多变量输出的隐马尔可夫过程 

定义隐藏状态动态的初始概率和条件转移概率.

In[1]:=

X p0 = {1/2, 1/2}; tm = {{3/4, 1/4}, {2/5, 3/5}};

定义分类输出的隐马尔可夫过程.

In[2]:=

X hmm1 = HiddenMarkovProcess[p0, tm, {{2/3, 1/3}, {0, 1}}];

定义普通离散输出的隐马尔可夫过程.

In[3]:=

X hmm2 = HiddenMarkovProcess[p0, tm, {GeometricDistribution[1/3], NegativeBinomialDistribution[5, 1/4]}];

定义连续输出的隐马尔可夫过程.

In[4]:=

X hmm3 = HiddenMarkovProcess[p0, tm, {NormalDistribution[2, 1], StudentTDistribution[-2, 1, 7]}];

定义多变量输出的隐马尔可夫过程.

In[5]:=

X hmm4 = HiddenMarkovProcess[p0, tm, {MultivariatePoissonDistribution[2, {5, 6}], NegativeMultinomialDistribution[6, {1/3, 1/4}]}];

In[6]:=

X hmm5 = HiddenMarkovProcess[p0, tm, {BinormalDistribution[{-1, 2}, {1, 1}, 1/2], BinormalDistribution[{2, -1}, {1, 1}, -1/2]}];

对每个隐马尔可夫过程取样.

In[7]:=

X procList = {hmm1, hmm2, hmm3, hmm4, hmm5};

In[8]:=

X pathList = Table[RandomFunction[proc, {0, 100}], {proc, procList}];

计算各过程路径的对数似然函数.

In[9]:=

X MapThread[LogLikelihood, {N[procList], pathList}]

Out[9]=

可视化单变量样本路径过程.

显示完整的 Wolfram 语言输入隐藏输入

In[10]:=

X Table[ListPlot[path, PlotTheme -> "Detailed", ImagePadding -> {{20, 5}, {20, 5}}], {path, Take[pathList, 3]}] // Row

Out[10]=

可视化多变量 emmisions 过程样本路径分量.

显示完整的 Wolfram 语言输入隐藏输入

In[11]:=

X labeledPlot[path_, lbl_] := Labeled[Column[ MapIndexed[ ListPlot[#1, PlotTheme -> "Detailed", ImagePadding -> {{20, 5}, {20, 5}}, PlotStyle -> ColorData[112][First[#2]]] &, path["PathComponents"]]], lbl]

In[12]:=

X Legended[MapThread[ labeledPlot, {Take[pathList, -2], {"Bivariate discrete", "Bivariate continuous"}}] // Row, SwatchLegend[ ColorData[112, "ColorList"], {"X-component", "Y-component"}]]

Out[12]=