離散／連続観測値，一変量／多変量観測値の隠れマルコフ過程 

隠れ状態の力学について，初期確率と条件付き遷移確率を定義する．

In[1]:=

X p0 = {1/2, 1/2}; tm = {{3/4, 1/4}, {2/5, 3/5}};

分類観測値を伴う隠れマルコフ過程を定義する．

In[2]:=

X hmm1 = HiddenMarkovProcess[p0, tm, {{2/3, 1/3}, {0, 1}}];

一般の離散観測値を伴う隠れマルコフ過程を定義する．

In[3]:=

X hmm2 = HiddenMarkovProcess[p0, tm, {GeometricDistribution[1/3], NegativeBinomialDistribution[5, 1/4]}];

連続観測値を伴う隠れマルコフ過程を定義する．

In[4]:=

X hmm3 = HiddenMarkovProcess[p0, tm, {NormalDistribution[2, 1], StudentTDistribution[-2, 1, 7]}];

多変量観測値を伴う隠れマルコフ過程を定義する．

In[5]:=

X hmm4 = HiddenMarkovProcess[p0, tm, {MultivariatePoissonDistribution[2, {5, 6}], NegativeMultinomialDistribution[6, {1/3, 1/4}]}];

In[6]:=

X hmm5 = HiddenMarkovProcess[p0, tm, {BinormalDistribution[{-1, 2}, {1, 1}, 1/2], BinormalDistribution[{2, -1}, {1, 1}, -1/2]}];

それぞれの隠れマルコフ過程を抽出する．

In[7]:=

X procList = {hmm1, hmm2, hmm3, hmm4, hmm5};

In[8]:=

X pathList = Table[RandomFunction[proc, {0, 100}], {proc, procList}];

それぞれの過程に対する各経路の対数尤度を計算する．

In[9]:=

X MapThread[LogLikelihood, {N[procList], pathList}]

Out[9]=

一変量観測値を伴う過程のサンプル経路を可視化する．

完全なWolfram言語入力を表示する入力を隠す

In[10]:=

X Table[ListPlot[path, PlotTheme -> "Detailed", ImagePadding -> {{20, 5}, {20, 5}}], {path, Take[pathList, 3]}] // Row

Out[10]=

多変量観測値を伴う過程のサンプル経路の成分を可視化する．

完全なWolfram言語入力を表示する入力を隠す

In[11]:=

X labeledPlot[path_, lbl_] := Labeled[Column[ MapIndexed[ ListPlot[#1, PlotTheme -> "Detailed", ImagePadding -> {{20, 5}, {20, 5}}, PlotStyle -> ColorData[112][First[#2]]] &, path["PathComponents"]]], lbl]

In[12]:=

X Legended[MapThread[ labeledPlot, {Take[pathList, -2], {"Bivariate discrete", "Bivariate continuous"}}] // Row, SwatchLegend[ ColorData[112, "ColorList"], {"X-component", "Y-component"}]]

Out[12]=