Processos ocultos de Markov com emissões discretas ou contínuas, univariadas ou multivariadas 

Defina as probabilidades iniciais e as probabilidades de transição condicional para as dinâmicas dos estados ocultos.

In[1]:=

X p0 = {1/2, 1/2}; tm = {{3/4, 1/4}, {2/5, 3/5}};

Defina processos ocultos de Markov com emissões categóricas.

In[2]:=

X hmm1 = HiddenMarkovProcess[p0, tm, {{2/3, 1/3}, {0, 1}}];

Defina processos ocultos de Markov com emissões discretas gerais.

In[3]:=

X hmm2 = HiddenMarkovProcess[p0, tm, {GeometricDistribution[1/3], NegativeBinomialDistribution[5, 1/4]}];

Defina processos ocultos de Markov com emissões contínuas.

In[4]:=

X hmm3 = HiddenMarkovProcess[p0, tm, {NormalDistribution[2, 1], StudentTDistribution[-2, 1, 7]}];

Defina processos ocultos de Markov com emissões multivariadas.

In[5]:=

X hmm4 = HiddenMarkovProcess[p0, tm, {MultivariatePoissonDistribution[2, {5, 6}], NegativeMultinomialDistribution[6, {1/3, 1/4}]}];

In[6]:=

X hmm5 = HiddenMarkovProcess[p0, tm, {BinormalDistribution[{-1, 2}, {1, 1}, 1/2], BinormalDistribution[{2, -1}, {1, 1}, -1/2]}];

Amostre cada processo oculto de Markov.

In[7]:=

X procList = {hmm1, hmm2, hmm3, hmm4, hmm5};

In[8]:=

X pathList = Table[RandomFunction[proc, {0, 100}], {proc, procList}];

Compute verossimilhança logarítmica de cada caminho para o respectivo processo.

In[9]:=

X MapThread[LogLikelihood, {N[procList], pathList}]

Out[9]=

Visualize exemplos de caminhos de processos com emissões univariadas.

mostre o input completo de Wolfram Languageoculte o input

In[10]:=

X Table[ListPlot[path, PlotTheme -> "Detailed", ImagePadding -> {{20, 5}, {20, 5}}], {path, Take[pathList, 3]}] // Row

Out[10]=

Visualize componentes de caminhos de processos com emissões multivariadas de exemplo.

mostre o input completo de Wolfram Languageoculte o input

In[11]:=

X labeledPlot[path_, lbl_] := Labeled[Column[ MapIndexed[ ListPlot[#1, PlotTheme -> "Detailed", ImagePadding -> {{20, 5}, {20, 5}}, PlotStyle -> ColorData[112][First[#2]]] &, path["PathComponents"]]], lbl]

In[12]:=

X Legended[MapThread[ labeledPlot, {Take[pathList, -2], {"Bivariate discrete", "Bivariate continuous"}}] // Row, SwatchLegend[ ColorData[112, "ColorList"], {"X-component", "Y-component"}]]

Out[12]=