有初始条件的时间序列过程 

Mathematica 10 支持给定过去值的时间序列过程，其中包括以过去值为条件的平稳时间序列以及有初始条件的的非平稳时间序列. 当自回归系数满足平稳条件时，最终有初始值的过程向平稳过程收敛.

定义一个有给定过去值的自回归过程.

In[1]:=

X ar\[ScriptCapitalP] = ARProcess[\[ScriptC], {r1 + r2, -r1 r2}, \[Sigma]^2, {Subscript[ y, -2], Subscript[y, -1]}]

Out[1]=

求过程的均值函数.

In[2]:=

X meanF = FunctionExpand[ar\[ScriptCapitalP][t] // Mean]

Out[2]=

作成均值函数的长期平稳性条件.

In[3]:=

X cond = Apply[And, Cases[meanF, b_^(t + s_.) :> (Abs[b] < 1), Infinity] // Union]

Out[3]=

验证这些条件与弱平稳性条件相同.

In[4]:=

X condR = Reduce[ a1 == r1 + r2 && a2 == -r1 r2 && cond && {a1, a2} \[Element] Reals, {a1, a2}, {r1, r2}, Backsubstitution -> True]

Out[4]=

In[5]:=

X Reduce[Equivalent[condR, WeakStationarity[ARProcess[c, {a1, a2}, \[Sigma]^2]]], {a1, a2}, Reals]

Out[5]=

可视化参数区域和处于内部、外部以及弱平稳性区域边界上的三个样本参数点.

In[6]:=

X RegionPlot[condR, {a1, -2, 2}, {a2, -2, 2}, Epilog -> {Red, PointSize[Medium], Point[{{0.1, -0.5}, {0.7, 0.6}, {-0.9, 0.1}}]}]

Out[6]=

可视化几个参数选择的样本轨迹.

In[7]:=

X {pInside, pOutside, pBoundary} = ARProcess[\[ScriptC], {a1, a2}, \[Sigma]^2, {Subscript[y, -2], Subscript[y, -1]}] /. {\[ScriptC] -> 1, \[Sigma] -> 1, Subscript[y, -1] -> -0.23, Subscript[y, -2] -> 0.8} /. {{a1 -> 0.1, a2 -> -0.5}, {a1 -> 0.7, a2 -> 0.6}, {a1 -> -0.9, a2 -> 0.1}}

Out[7]=

In[8]:=

X {Table[ListPlot[RandomFunction[p, {0, 100}, 3], Filling -> Axis], {p, {pInside, pOutside, pBoundary}}], {"Inside", "Outside", "Boundary"}} // Grid

Out[8]=

可视化这些参数选择的均值函数.

In[9]:=

X {Table[DiscretePlot[Mean[p[t]], {t, 0, 30}, PlotRange -> All], {p, {pInside, pOutside, pBoundary}}], {"Inside", "Outside", "Boundary"}} // Grid

Out[9]=