Proceso vectorial autorregresivo como proceso discretizado vectorial Ornstein-Uhlenbeck 

El soporte mejorado para computación con segmentos de procesos, así como soporte para procesos arbitrarios de series temporales promedio y procesos de tiempo con valores iniciales, permite la correspondencia de un proceso gaussiano Ito discretizado uniformemente con un proceso autorregresivo con valores de vector.

Defina un proceso Ito en 2D con coeficientes de deriva lineales y coeficientes de difusión constantes.

In[1]:=

X itoPr = ItoProcess[{{1 - (5 x1[t] + 3 x2[t])/ 4, -1 - (3 x1[t] + 5 x2[t])/4}, {{1, 0}, {Sqrt[3], 1}}, {x1[t], x2[t]}}, {{x1, x2}, {0, 1/2}}, {t, 0}];

Defina un proceso autorregresivo bivariable con valores iniciales.

In[2]:=

X varPr = ARProcess[{c1, c2}, {{{a11, a12}, {a21, a22}}}, {{s1, s12}, {s12, s2}}, {{x10ar, x20ar}}];

Dado que ambos procesos son gaussianos, ellos están completamente especificados por su media y funciones covariantes.

In[3]:=

X itoPrmf[t_] = Mean[itoPr[t]];

In[4]:=

X itoPrcovF[s_, t_] = Simplify[CovarianceFunction[itoPr, s, t]];

In[5]:=

X varPrmf[n_] = Mean[varPr[n]];

In[6]:=

X varPrcovF[n_, m_] = Simplify[CovarianceFunction[varPr, n, m]];

Construya ecuaciones de momentos al igualar funciones de momentos de procesos Ito en tiempos espaciados regularmente y funciones de momentos VAR en números enteros consecutivos.

In[7]:=

X dt = 1/1000;

In[8]:=

X meanEqs = Table[itoPrmf[n dt] == varPrmf[n - 1], {n, 4}]; covEqs = Table[ Flatten[itoPrcovF[n dt, m dt]] == Flatten[varPrcovF[n - 1, m - 1]], {n, 4}, {m, n, 4}];

Resuelva las ecuaciones.

In[9]:=

X {sol} = NSolve[ Join[meanEqs, Flatten[covEqs]], {c1, c2, x10ar, x20ar, a11, a12, a21, a22, s1, s2, s12}]

Out[9]=

La simulación de procesos VAR provee una simulación exacta del proceso Ito de un grid regular.

In[10]:=

X path = RandomFunction[varPr /. sol, {0, 20000}]

Out[10]=

Visualice el camino.

muestre la entrada completa de Wolfram Languageoculte la entrada

In[11]:=

X Legended[Graphics[{{Gray, Line[path["Values"]]}, {Red, PointSize[.03], Point[{x10ar, x20ar} /. sol]}, {Orange, PointSize[.03], Point[Limit[itoPrmf[t], t -> Infinity]]} }, AspectRatio -> 1, Frame -> True, ImageSize -> Medium], LineLegend[{Red, Orange, Gray}, {"starting point", "stationary mean", "process path"}, Joined -> {False, False, True}]]

Out[11]=