Processo autorregressivo vetorial como processo Ornstein–Uhlenbeck vetorial discretizado 

O suporte aprimorado para computação com fatias de processo, bem como o suporte a processos de séries temporais de média arbitrária e processos temporais com valores iniciais, permitem a correspondência de um processo de Ito Gaussiano uniformemente discretizado a um processo autorregressivo vetorial.

Defina um processo de Ito 2D com coeficientes de desvio linear e coeficientes de difusão constante.

In[1]:=

X itoPr = ItoProcess[{{1 - (5 x1[t] + 3 x2[t])/ 4, -1 - (3 x1[t] + 5 x2[t])/4}, {{1, 0}, {Sqrt[3], 1}}, {x1[t], x2[t]}}, {{x1, x2}, {0, 1/2}}, {t, 0}];

Defina um processo autorregressivo bivariado com valores iniciais.

In[2]:=

X varPr = ARProcess[{c1, c2}, {{{a11, a12}, {a21, a22}}}, {{s1, s12}, {s12, s2}}, {{x10ar, x20ar}}];

Uma vez que ambos os processos são gaussianos, eles são completamente especificados pelas suas funções de covariância e de média.

In[3]:=

X itoPrmf[t_] = Mean[itoPr[t]];

In[4]:=

X itoPrcovF[s_, t_] = Simplify[CovarianceFunction[itoPr, s, t]];

In[5]:=

X varPrmf[n_] = Mean[varPr[n]];

In[6]:=

X varPrcovF[n_, m_] = Simplify[CovarianceFunction[varPr, n, m]];

Construa equações de momentos igualando as funções de momento do processo de Ito em períodos regularmente espaçados e as funções de momento VAR em inteiros consecutivos.

In[7]:=

X dt = 1/1000;

In[8]:=

X meanEqs = Table[itoPrmf[n dt] == varPrmf[n - 1], {n, 4}]; covEqs = Table[ Flatten[itoPrcovF[n dt, m dt]] == Flatten[varPrcovF[n - 1, m - 1]], {n, 4}, {m, n, 4}];

Resolva as equações.

In[9]:=

X {sol} = NSolve[ Join[meanEqs, Flatten[covEqs]], {c1, c2, x10ar, x20ar, a11, a12, a21, a22, s1, s2, s12}]

Out[9]=

A simulação do processo VAR fornece uma simulação exata do processo de Ito da grelha regular.

In[10]:=

X path = RandomFunction[varPr /. sol, {0, 20000}]

Out[10]=

Visualize o caminho.

mostre o input completo de Wolfram Languageoculte o input

In[11]:=

X Legended[Graphics[{{Gray, Line[path["Values"]]}, {Red, PointSize[.03], Point[{x10ar, x20ar} /. sol]}, {Orange, PointSize[.03], Point[Limit[itoPrmf[t], t -> Infinity]]} }, AspectRatio -> 1, Frame -> True, ImageSize -> Medium], LineLegend[{Red, Orange, Gray}, {"starting point", "stationary mean", "process path"}, Joined -> {False, False, True}]]

Out[11]=