Wolfram Language™

Récepteurs GPS et élévation

Les récepteurs GPS mesurent les positions par rapport à un point de référence ellipsoïdal approchant la surface de la Terre. Toutefois, les élévations par rapport à l'ellipsoïde ne sont pas d'un usage pratique directe, par exemple l'élévation de la surface d'un lac n'est pas constante par rapport à l'ellipsoïde. Nous devons convertir cette élévation à une autre surface de référence, le géoïde, qui se rapproche du niveau moyen de la mer jusqu'à l'intérieur des terres.

L'élévation du géoïde par rapport à l'ellipsoïde de référence est appelée «ondulation». Téléchargez les données ondulatoires en pieds pour les États américains limitrophes.

In[1]:=

undulation = GeoElevationData[Entity["Country", "UnitedStates"], "Undulation"]

Out[1]=

Le géoïde est toujours sous l'ellipsoïde de référence dans la région des États-Unis.

In[2]:=

MinMax[undulation]

Out[2]=

En particulier, c'est l'ondulation au siège central de Wolfram à Champaign.

In[3]:=

GeoElevationData[ GeoPosition[ Entity["City", {"Champaign", "Illinois", "UnitedStates"}]], "Undulation"]

Out[3]=

Téléchargez des données du monde entier.

In[4]:=

undulation = GeoElevationData["World", "Undulation"]

Out[4]=

Représentez comme une carte en relief.

In[5]:=

image = ReliefPlot[undulation, DataReversed -> True, PlotRangePadding -> None, PlotLegends -> Automatic, MaxPlotPoints -> Infinity, Frame -> False]

Out[5]=

Utilisez une projection géo différente.

In[6]:=

With[{bounds = {{-90, 90}, {-180, 180}}}, Legended[GeoGraphics[{GeoStyling[{"GeoImage", image[[1]]}, GeoRange -> bounds], GeoBoundsRegion[bounds]}, GeoRange -> bounds, GeoProjection -> "WinkelTripel", GeoGridLines -> True, ImageSize -> Medium], image[[2]]]]

Out[6]=