Wolfram Language™

Combien cela pèse-t-il ?

Le poids d'un objet dans un champ gravitationnel est le produit de sa masse et de la valeur du champ gravitationnel à la position de l'objet. À la surface de la Terre, le champ gravitationnel n'est pas constant et, par conséquent, le même objet a un poids différent selon l'endroit où il se trouve. Cet exemple explore la variabilité de l'amplitude du champ gravitationnel en fonction de l'altitude et de la latitude.

GeogravityModelData calcule plusieurs propriétés du champ gravitationnel de la Terre à un endroit donné.

In[1]:=

GeogravityModelData[GeoPosition[{0, 0}]]

Out[1]=

Il utilise l'élévation topographique fournie par GeoElevationData.

In[2]:=

GeoElevationData[GeoPosition[{0, 0}]]

Out[2]=

Si l'on ignore les autres effets, le champ gravitationnel est généralement plus faible pour un lieu situé à une latitude similaire mais à une altitude plus élevée.

In[3]:=

GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]]

Out[3]=

In[4]:=

GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]]; {GeoElevationData[%, UnitSystem -> "Metric"], GeogravityModelData[%, "Magnitude"]}

Out[4]=

Calculez les valeurs de la magnitude du champ gravitationnel à des points équidistants sur l'équateur.

In[5]:=

equatorialgravity = GeogravityModelData[{GeoPosition[{0, -180}], GeoPosition[{5, 180}]}, "Magnitude"][[1]]

Out[5]=

In[6]:=

ListPlot[equatorialgravity, Joined -> True]

Out[6]=

Dans l'histogramme suivant, on observe deux pics principaux, correspondant aux zones terrestres et au fond des océans.

In[7]:=

Histogram[equatorialgravity, 20]

Out[7]=

Superposez la magnitude du champ gravitationnel sur une carte en relief de la Terre.

In[8]:=

equatorialgravityplot = ListPlot[equatorialgravity, Axes -> False, Joined -> True, AspectRatio -> 1/8, PlotRangePadding -> None, ImagePadding -> None, ImageSize -> 400, PlotStyle -> Red];

In[9]:=

worldmap = GeoGraphics[GeoPath["Equator"], GeoRange -> "World", ImageSize -> 400, GeoBackground -> "ReliefMap"];

In[10]:=

Overlay[{worldmap, equatorialgravityplot}, Alignment -> Center]

Out[10]=

Pour montrer la variabilité en fonction de la latitude, faites la moyenne de l'amplitude du champ gravitationnel sur la longitude et représentez le résultat en fonction de la latitude.

In[11]:=

gravity = Mean /@ GeogravityModelData[{GeoPosition[{-90, -180}], GeoPosition[{90, 180}]}, "Magnitude"];

L'Antarctique a un effet évident sur les basses latitudes, en raison de l'altitude supplémentaire.

In[12]:=

ListPlot[gravity, DataRange -> {-90, 90}]

Out[12]=

In[13]:=

MinMax[gravity]

Out[13]=

Par conséquent, il peut y avoir des changements de l'ordre de 0,5% du poids d'un objet donné, selon l'endroit où nous le mesurons.

In[14]:=

MinMax[gravity]; 1 - First[%]/Last[%]