Wolfram Language™

Seul sur Mars

Calculez, représentez et mesurez une estimation de la trajectoire suivie par Mark Watney dans le livre Seul sur Mars lorsqu'il se rend de l'Ares 3 HAB à l'Ares 4 MAV.

Dans cet exemple, toutes les positions se réfèrent à des positions sur Mars. Cela peut être spécifié explicitement dans GeoPosition, ou plus tard grâce à l'option GeoModel.

Il s'agit d'estimations des positions des atterrissages Ares 3 et 4.

In[1]:=

ares3 = GeoPosition[{31.2, -28.5}, "Mars"]; ares4 = GeoPosition[{-4.32, 15.28}, "Mars"];

Il s'agit donc de la première approximation du voyage de Mark sur Mars.

In[2]:=

GeoGraphics[{Orange, Thick, Arrow@GeoPath[{ares3, ares4}]}, GeoRange -> All, GeoProjection -> "Orthographic", Background -> Black]

Out[2]=

Depuis le HAB Ares 3, Mark suit une vallée creusée par l'eau appelée Mawrth Vallis.

In[3]:=

mawrthVallis = GeoPosition[CompressedData[" 1:eJxTTMoPSmViYGCQAGIQLd/6OnCHnJXDN42Y/kOlxgdsua4vLvhr6QAkbbnE jQ8wgMABS4d17g+rRNYZHZg1EwgiLaHqjQ5wgRVaOhz+ChRwMoKqt3BYAhS9 rmx0AKTLPdHCoRBksIHRgf5DQIX8Fg4iIANDjA5oAo35usLcAaLO6EDQDjmg ixD8s2eAgMccrj4NBJ6Zwc0DK99h5vAmEMQyPACmV5s5gN3RYAixf6GZA8Re wwNgdzbB5A0OGINAsZkDxB8GEPf5m0H8H64P9Z8ZxH+H9CDqN5tC/at3AOIu U0h4fNWF2Kdo6uABYhzXhaj/bAL1jy5E/RUTB3A4ztQ5AAD2PaQO "]];

In[4]:=

GeoGraphics[{Thick, Orange, Arrow@GeoPath[mawrthVallis]}, GeoModel -> "Mars", GeoRangePadding -> Quantity[100, "Miles"]]

Out[4]=

Ensuite, Mark passe entre les cratères Trouvelot et Rutherford.

In[5]:=

GeoPosition /@ {Entity["SolarSystemFeature", "TrouvelotMars"], Entity["SolarSystemFeature", "RutherfordMars"]}

Out[5]=

In[6]:=

rtCraters = GeoPosition[{17.52, -11.91}, "Mars"];

Puis, il se déplace vers le cratère Marth.

In[7]:=

marthCrater = GeoPosition[Entity["SolarSystemFeature", "MarthMars"]]

Out[7]=

De là, il parcourt 540 kilomètres au sud.

In[8]:=

pos540S = GeoDestination[marthCrater, GeoDisplacement[{Quantity[540, "Kilometers"], "South"}]]

Out[8]=

Et enfin, il se rapproche du cratère Schiaparelli.

In[9]:=

schiaparelliCrater = GeoPosition[{-0.16, 14.38}, "Mars"]

Out[9]=

In[10]:=

geopath = GeoPath[{{ares3, mawrthVallis[[1, 1]]}, mawrthVallis, {mawrthVallis[[1, -1]], rtCraters, marthCrater, pos540S, schiaparelliCrater, ares4}}];

Ce trajet géographique a la longueur suivante sur la surface de Mars.

In[11]:=

GeoLength[geopath, GeoModel -> "Mars"]

Out[11]=

Pour finir, ajoutez un certain nombre de lieux mentionnés dans le livre, avec des étiquettes respectives.

In[12]:=

labeled[pos_, label_, offset_: {Left, Bottom}] := {Point[pos], Text[Style[label, Directive[12, Italic, White]], pos, offset]}

In[13]:=

points = labeled @@@ Join[EntityValue[{Entity["SolarSystemFeature", "ArabiaTerraMars"], Entity["DeepSpaceProbe", "MarsPathfinder"], Entity["DeepSpaceProbe", "MERDashBOpportunityRover"], Entity["SolarSystemFeature", "TerraMeridianiMars"], Entity["SolarSystemFeature", "RutherfordMars"], Entity["SolarSystemFeature", "BecquerelMars"], Entity["SolarSystemFeature", "TrouvelotMars"], Entity["SolarSystemFeature", "MarthMars"]}, {"Position", "Name"}], { {ares3, "Ares 3 HAB"}, {ares4, "Ares 4 MAV", {Right, Bottom}}}];

Voici la carte finale du voyage.

In[14]:=

GeoGraphics[{Orange, Thick, geopath, PointSize[Large], points}, GeoModel -> "Mars"]

Out[14]=