Solución de ecuaciones diferenciales parciales con eventos sobre regiones: Nuevo en Wolfram Language 11

Solución de ecuaciones diferenciales parciales con eventos sobre regiones

Modele la generación de calor controlada por termostato en una habitación con tres paredes aislantes y un frente de vidrio sujeto a la temperatura exterior.

In[1]:=

\[CapitalOmega] = Rectangle[{0, 0}, {3/2, 1}];
outsideTemp[t_] := 15 + 10*Sin[2 \[Pi] t/24];
kd = 0.78; Ld = 0.05;
\[CapitalGamma] = 
  NeumannValue[Ld/kd*(outsideTemp[t] - u[t, x, y]), {x == 0}];

Una carga de radiador se intensifica y disminuye en un evento.

In[2]:=

heaterLoad = 26;
heater[upQ_, t_, tEvent_] := 
 If[upQ == 1, Min[20*Max[(t - tEvent), 0], 1], 
   1 - Min[20*Max[(t - tEvent - 1/8), 0], 1]]*heaterLoad

La ecuación diferencial parcial modela la difusión de calor por medio del aire, mientras se genera calor dentro de un círculo y se pierde calor por medio de la ventana de vidrio.

In[3]:=

\[Rho] = 1.225; Cp = 1005.4;
With[{heating = heater[a[t], t, eventT[t]]},
  pde = D[u[t, x, y], t] - \[Rho]*Cp*Laplacian[u[t, x, y], {x, y}] == 
    If[(x - 1/2)^2 + (y - 1/2)^2 <= (2/10)^2, heating, 
      0] + \[CapitalGamma]];

Si el termostato en posición mide una temperatura por debajo/por encima del activador, y su variable discreta cambia, el calentador es apagado/encendido.

In[4]:=

triggerLow = 18; triggerHigh = 20;
events = {a[0] == 1, eventT[0] == 0, 
   WhenEvent[
    u[t, 1.25, .25] < 
     triggerLow, {eventT[t], a[t]} -> {If[a[t] == 0, t, eventT[t]], 
      1}], WhenEvent[
    u[t, 1.25, .25] > 
     triggerHigh, {eventT[t], a[t]} -> {If[a[t] == 1, t, eventT[t]], 
      0}]};

Monitoree el tiempo de integración de la ecuación diferencial parcial con una condición inicial igual a la temperatura exterior.

In[5]:=

eqn = {pde, u[0, x, y] == outsideTemp[0], events};
res = Monitor[
  NDSolveValue[
   eqn, {u, a}, {t, 0, 2*24}, {x, y} \[Element] \[CapitalOmega], 
   DiscreteVariables -> {eventT[t], a[t]}, 
   EvaluationMonitor :> (monitor = Row[{"t = ", CForm[t]}])], monitor]

Out[5]=

Visualice la temperatura medida por el termostato, la temperatura exterior, y los activadores para el calentador. Un fondo azul se muestra cuando el calentador se enciende.

In[6]:=

hp = Plot[ 25 res[[2]][t], {t, 0, 2*24}, Filling -> Bottom, 
  PlotStyle -> None]; Show[
 Plot[{res[[1]][t, 1.25, .25], outsideTemp[t], 18, 20}, {t, 0, 
   2*24}], hp]

Out[6]=