Wolfram Language™

Réacteurs nucléaires du monde

NuclearReactorData fournit des données sur les réacteurs nucléaires connus dans le monde entier. Certains d'entre eux ont déjà été fermés, comme celui de Tchernobyl. Vous pouvez sélectionner les réacteurs qui sont actuellement opérationnels pour l'analyse des ressources énergétiques nucléaires.

In[1]:=

reactors = NuclearReactorData[];

In[2]:=

active = Select[reactors, #["Status"] == "operational" &];

Extrayez la production annuelle d'énergie et le pays où cela se trouve.

In[3]:=

annualproduction = NuclearReactorData[active, "AnnualEnergyProduction"]; countries = Map[First, NuclearReactorData[active, "Countries"]];

Créez un ensemble de données et de supprimez les points de données qui contiennent des valeurs manquantes. Le nombre de réacteurs en fonction est supérieur à 400.

In[4]:=

data = Transpose[{active, countries, annualproduction}]; data = DeleteMissing[data, 1, 2];

In[5]:=

data // Dimensions

Out[5]=

Le nombre de réacteurs par pays.

In[6]:=

percountry = GroupBy[data, #1[[2]] &];

In[7]:=

numberpercountry = Map[Length, percountry];

In[8]:=

BarChart[Sort[numberpercountry], ChartLabels -> Automatic, ChartStyle -> "DarkRainbow", BarOrigin -> Left, BarSpacing -> 1, LabelingFunction -> (Placed[#1, After] &), ImageSize -> Large]

Out[8]=

Le nombre de réacteurs correspond à l'énergie nucléaire totale produite par pays.

In[9]:=

energytotals = Map[Total[#[[All, 3]]] &, percountry];

In[10]:=

stats = {Min, Max, Mean, Median, Total}; TableForm[#[energytotals] & /@ stats, TableHeadings -> {stats}]

Out[10]//TableForm=

Les plus grands producteurs de l'énergie nucléaire sont les États-Unis et en France.

In[11]:=

TakeLargest[energytotals, 2]

Out[11]=

In[12]:=

GeoRegionValuePlot[energytotals, GeoProjection -> "Mercator", GeoRange -> {{-70, 80}, {-170, 190}}, GeoLabels -> (Tooltip[#1, #2] &)]

Out[12]=

La carte est différente si l'on considère la production totale d'énergie par habitant. Utilisez CountryData pour accéder à des totaux de population pour chaque pays sur la liste.

In[13]:=

populations = AssociationThread[Keys[energytotals], CountryData[#, "Population"] & /@ Keys[energytotals]];

Calculez l'énergie nucléaire par habitant.

In[14]:=

energypercapita = energytotals/populations;

In[15]:=

TableForm[#[energypercapita] & /@ stats, TableHeadings -> {stats}]

Out[15]//TableForm=

Sur la carte, vous pouvez voir que même si les États-Unis a la plus grande production absolue de l'énergie nucléaire, mais ce n'est pas la plus grande par personne, où la France et la Suède sont en tête.

In[16]:=

TakeLargest[energypercapita, 2]

Out[16]=

In[17]:=

GeoRegionValuePlot[energypercapita, GeoProjection -> "Mercator", GeoRange -> {{-70, 80}, {-170, 190}}, GeoLabels -> (Tooltip[#1, #2] &)]

Out[17]=