Wolfram Language™

Conjuntos de Gauss (GOE, GUE, ...)

Os conjuntos de Gauss são famílias de matrizes aleatórias normalmente distribuídas com distribuições invariantes sob diferentes transformações unitárias. Elas são bem estudadas, em parte devido à tratabilidade analítica, mas também devido aos espectros associados que se aproximam bastante a muitos sistemas com grandes graus de liberdade. Exemplos destes sistemas são encontrados na física, finanças, e biologia.

Matrizes de um conjunto ortogonal de Gauss (GOE) são simétricos. »

In[1]:=

goe = RandomVariate[GaussianOrthogonalMatrixDistribution[5]];

In[2]:=

SymmetricMatrixQ[goe]

Out[2]=

Matrizes de um conjunto unitário de Gauss (GUE) são hermitianas. »

In[3]:=

gue = RandomVariate[GaussianUnitaryMatrixDistribution[5]];

In[4]:=

HermitianMatrixQ[gue]

Out[4]=

Matrizes de um conjunto simplético de Gauss (GSE) são simplécticas hermitianas. »

In[5]:=

symplecticMatrixQ[m_] := With[{\[ScriptCapitalJ] = KroneckerProduct[{{0, -1}, {1, 0}}, IdentityMatrix[Length[m]/2]]}, Conjugate[m].\[ScriptCapitalJ] == \[ScriptCapitalJ].m ];

In[6]:=

gse = RandomVariate[GaussianSymplecticMatrixDistribution[5]];

In[7]:=

symplecticMatrixQ[gse] && HermitianMatrixQ[gse]

Out[7]=

Distribuição de valores próprios para matrizes de conjuntos de Gauss em pequenas dimensões.

In[8]:=

eigs = Flatten[ RandomVariate[ MatrixPropertyDistribution[Eigenvalues[x], x \[Distributed] #], 10^5]] & /@ {GaussianOrthogonalMatrixDistribution[4], GaussianUnitaryMatrixDistribution[4], GaussianSymplecticMatrixDistribution[4]}; Row[MapThread[ SmoothHistogram[#1, "Scott", Frame -> None, PlotLegends -> Placed[#2, Above], Filling -> Axis, FillingStyle -> Green] &, {eigs, {Style["Orthogonal", 15], Style["Unitary", 15], Style["Symplectic", 15]}}]]

Out[8]=