Die Bewegung der Spieler in Ego-Shooter-Spielen verfolgen 

In einem Ego-Shooter-Spiel ist in einem bestimmten Level ein Agent versteckt und wartet darauf, den Spieler anzugreifen. Der Agent kann den Spieler nicht sehen, aber dessen Bewegungen wahrnehmen und in Kombination mit seiner Kenntnis des Spiellayouts daraus die Position des Spielers abschätzen. Angenommen sei ein Layout mit 27 Bereichen, die 4 verschiedenen Typen entsprechen – nämlich Gras, Metallgittern, Wasser und Türportalen.

Die gesamte Wolfram-Language Eingabe zeigenEingabe verbergen

In[1]:=

X grass = Alternatives[1, 2, 4, 5, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20]; metal = Alternatives[3, 6, 21, 22, 24, 25]; water = Alternatives[7, 8, 9, 10]; door = Alternatives[23, 26, 27];

Ordnen Sie den verschiedenen Bereichstypen unterschiedliche Farben zu.

In[2]:=

X colors = Transpose[{{grass, Green}, {metal, Gray}, {water, Blue}, {door, Brown}}];

Je nach Beschaffenheit des Bereichs ändert sich der Klang von Schritten.

In[3]:=

X {none, footsteps, splashing, creaking, unclear} = Range[5];

Die Wahrscheinlichkeit, ein Geräusch zu erzeugen, hängt also vom Bereich ab.

In[4]:=

X em = SparseArray[{ {{grass, none}, {grass, unclear}} -> {0.9, 0.1}, {{metal, none}, {metal, footsteps}} -> {0.1, 0.9}, {{water, splashing}, {water, unclear}} -> {0.9, 0.1}, {{door, creaking}, {door, unclear}} -> {0.9, 0.1}}, {27, 5}];

Visualisieren Sie das Layout des Levels.

Die gesamte Wolfram-Language Eingabe zeigenEingabe verbergen

In[5]:=

X edges = {27 <-> 1, 1 <-> 2, 2 <-> 3, 3 <-> 4, 3 <-> 7, 4 <-> 5, 5 <-> 25, 25 <-> 24, 24 <-> 22, 22 <-> 21, 21 <-> 23, 21 <-> 20, 20 <-> 19, 19 <-> 18, 18 <-> 17, 17 <-> 7, 17 <-> 8, 18 <-> 9, 19 <-> 10, 10 <-> 9, 9 <-> 8, 8 <-> 7, 10 <-> 26, 10 <-> 14, 9 <-> 14, 8 <-> 13, 8 <-> 12, 14 <-> 15, 15 <-> 16, 14 <-> 13, 13 <-> 12, 13 <-> 11, 12 <-> 11, 11 <-> 6, 6 <-> 1};

In[6]:=

X regions = Range[27] /. MapThread[vert : #1 :> Style[vert, #2] &, colors];

In[7]:=

X gr = Graph[regions, edges, VertexSize -> Large, VertexLabels -> Placed["Name", Above], VertexShapeFunction -> "Square"]

Out[7]=

Angenommen, der Spieler betritt das Level mit gleicher Wahrscheinlichkeit durch eine der Türen.

In[8]:=

X p0 = SparseArray[{door -> 1/Length[door]}, 27];

Der Spieler bleibt mit einer Wahrscheinlichkeit von 10 % im aktuellen Bereich. Die Wahrscheinlichkeit, dass er eine der angrenzenden Bereiche betritt, ist gleichverteilt.

In[9]:=

X adjm = AdjacencyMatrix[gr]; tm = 0.9 adjm/Total[adjm, {2}] + 0.1 IdentityMatrix[27];

In[10]:=

X hmm = HiddenMarkovProcess[p0, tm, em];

Der Agent hört die folgende Geräuschsequenz:

In[11]:=

X obs = {creaking, none, footsteps, none, none, splashing, splashing, footsteps, splashing};

Demzufolge ist es am wahrscheinlichsten, dass der Spieler durch die Tür mit Nummer 27 das Level betreten hat und sich derzeit in Bereich 7 aufhält.

In[12]:=

X FindHiddenMarkovStates[obs, hmm] /. MapThread[v : #1 :> Framed[v, FrameStyle -> #2] &, colors]

Out[12]=