跟踪第一人称射击游戏中的玩家动作 

在第一人称射击游戏中，一名特工隐藏在某层准备突袭玩家. 特工虽然看不见玩家，但是可以听到其动作，并凭借对布局的了解估计玩家的位置. 设想一个由四种类型（草地、金属栅栏、水和大门）构成的27个区域的布局.

显示完整的 Wolfram 语言输入隐藏输入

In[1]:=

X grass = Alternatives[1, 2, 4, 5, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20]; metal = Alternatives[3, 6, 21, 22, 24, 25]; water = Alternatives[7, 8, 9, 10]; door = Alternatives[23, 26, 27];

给不同类型的区域分配颜色.

In[2]:=

X colors = Transpose[{{grass, Green}, {metal, Gray}, {water, Blue}, {door, Brown}}];

在不同的地形上行走会发出不同类型的声音.

In[3]:=

X {none, footsteps, splashing, creaking, unclear} = Range[5];

发出声音的概率取决于地形类型.

In[4]:=

X em = SparseArray[{ {{grass, none}, {grass, unclear}} -> {0.9, 0.1}, {{metal, none}, {metal, footsteps}} -> {0.1, 0.9}, {{water, splashing}, {water, unclear}} -> {0.9, 0.1}, {{door, creaking}, {door, unclear}} -> {0.9, 0.1}}, {27, 5}];

可视化水平布局.

显示完整的 Wolfram 语言输入隐藏输入

In[5]:=

X edges = {27 <-> 1, 1 <-> 2, 2 <-> 3, 3 <-> 4, 3 <-> 7, 4 <-> 5, 5 <-> 25, 25 <-> 24, 24 <-> 22, 22 <-> 21, 21 <-> 23, 21 <-> 20, 20 <-> 19, 19 <-> 18, 18 <-> 17, 17 <-> 7, 17 <-> 8, 18 <-> 9, 19 <-> 10, 10 <-> 9, 9 <-> 8, 8 <-> 7, 10 <-> 26, 10 <-> 14, 9 <-> 14, 8 <-> 13, 8 <-> 12, 14 <-> 15, 15 <-> 16, 14 <-> 13, 13 <-> 12, 13 <-> 11, 12 <-> 11, 11 <-> 6, 6 <-> 1};

In[6]:=

X regions = Range[27] /. MapThread[vert : #1 :> Style[vert, #2] &, colors];

In[7]:=

X gr = Graph[regions, edges, VertexSize -> Large, VertexLabels -> Placed["Name", Above], VertexShapeFunction -> "Square"]

Out[7]=

假设玩家以相同概率从其中一扇门进入.

In[8]:=

X p0 = SparseArray[{door -> 1/Length[door]}, 27];

玩家保持在目前区域的概率为 10%，否则向任意相邻区域移动的概率相同.

In[9]:=

X adjm = AdjacencyMatrix[gr]; tm = 0.9 adjm/Total[adjm, {2}] + 0.1 IdentityMatrix[27];

In[10]:=

X hmm = HiddenMarkovProcess[p0, tm, em];

特工听到以下噪声序列.

In[11]:=

X obs = {creaking, none, footsteps, none, none, splashing, splashing, footsteps, splashing};

这表示玩家可能从标号为27的门进入，并且当前所在区域为7.

In[12]:=

X FindHiddenMarkovStates[obs, hmm] /. MapThread[v : #1 :> Framed[v, FrameStyle -> #2] &, colors]

Out[12]=