ファーストパーソン・シューティングゲームでプレーヤーの動きを追跡する 

ファーストパーソン・シューティングゲームでは，エージェントがレベル内に隠れて，プレーヤーに飛び掛るチャンスを待っている．エージェントはプレーヤーが見えないが音は聞こえるので，既知のレイアウトに照らし合わせて，プレーヤーの位置を推測することができる．4つのタイプ（芝生，鉄格子，水，ドアの門）の27区域があるレイアウトを考える．

完全なWolfram言語入力を表示する入力を隠す

In[1]:=

X grass = Alternatives[1, 2, 4, 5, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20]; metal = Alternatives[3, 6, 21, 22, 24, 25]; water = Alternatives[7, 8, 9, 10]; door = Alternatives[23, 26, 27];

それぞれの区域のタイプに色を割り当てる．

In[2]:=

X colors = Transpose[{{grass, Green}, {metal, Gray}, {water, Blue}, {door, Brown}}];

歩く地面の種類によって，出る音が異なる．

In[3]:=

X {none, footsteps, splashing, creaking, unclear} = Range[5];

音が発生する確率は地面のタイプによる．

In[4]:=

X em = SparseArray[{ {{grass, none}, {grass, unclear}} -> {0.9, 0.1}, {{metal, none}, {metal, footsteps}} -> {0.1, 0.9}, {{water, splashing}, {water, unclear}} -> {0.9, 0.1}, {{door, creaking}, {door, unclear}} -> {0.9, 0.1}}, {27, 5}];

レベルのレイアウトを可視化する．

完全なWolfram言語入力を表示する入力を隠す

In[5]:=

X edges = {27 <-> 1, 1 <-> 2, 2 <-> 3, 3 <-> 4, 3 <-> 7, 4 <-> 5, 5 <-> 25, 25 <-> 24, 24 <-> 22, 22 <-> 21, 21 <-> 23, 21 <-> 20, 20 <-> 19, 19 <-> 18, 18 <-> 17, 17 <-> 7, 17 <-> 8, 18 <-> 9, 19 <-> 10, 10 <-> 9, 9 <-> 8, 8 <-> 7, 10 <-> 26, 10 <-> 14, 9 <-> 14, 8 <-> 13, 8 <-> 12, 14 <-> 15, 15 <-> 16, 14 <-> 13, 13 <-> 12, 13 <-> 11, 12 <-> 11, 11 <-> 6, 6 <-> 1};

In[6]:=

X regions = Range[27] /. MapThread[vert : #1 :> Style[vert, #2] &, colors];

In[7]:=

X gr = Graph[regions, edges, VertexSize -> Large, VertexLabels -> Placed["Name", Above], VertexShapeFunction -> "Square"]

Out[7]=

プレーヤーは各ドアから同じ確率で入るものと想定する．

In[8]:=

X p0 = SparseArray[{door -> 1/Length[door]}, 27];

プレーヤーは10%の確率で現在の区域に留まる．それ以外は隣接する区域のいずれかに同じ確率で移動する．

In[9]:=

X adjm = AdjacencyMatrix[gr]; tm = 0.9 adjm/Total[adjm, {2}] + 0.1 IdentityMatrix[27];

In[10]:=

X hmm = HiddenMarkovProcess[p0, tm, em];

エージェントは以下の音を聞く．

In[11]:=

X obs = {creaking, none, footsteps, none, none, splashing, splashing, footsteps, splashing};

これにより，プレーヤーは27番のドアから入り，現在区域7にいるであろうことが分かる．

In[12]:=

X FindHiddenMarkovStates[obs, hmm] /. MapThread[v : #1 :> Framed[v, FrameStyle -> #2] &, colors]

Out[12]=