Siga o movimento do jogador em um jogo de tiro de primeira pessoa 

Em um jogo de tiro de primeira pessoa, um agente está se escondendo dentro de um nível e esperando para pular contra o jogador. O agente não pode ver o jogador, mas pode ouvir o que está fazendo e assim usar esse conhecimento junto a seu conhecimento do ambiente para estimar a posição do jogador. Considere um ambiente com 27 regiões de quatro tipos—grama, grades de metal, água e portais.

mostre o input completo de Wolfram Languageoculte o input

In[1]:=

X grass = Alternatives[1, 2, 4, 5, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20]; metal = Alternatives[3, 6, 21, 22, 24, 25]; water = Alternatives[7, 8, 9, 10]; door = Alternatives[23, 26, 27];

Atribua cores para os diferentes tipos de regiões.

In[2]:=

X colors = Transpose[{{grass, Green}, {metal, Gray}, {water, Blue}, {door, Brown}}];

Andar sobre os diferentes tipos de terreno produz diferentes tipos de sons.

In[3]:=

X {none, footsteps, splashing, creaking, unclear} = Range[5];

As probabilidades de emitir sons dependem do tipo de terreno.

In[4]:=

X em = SparseArray[{ {{grass, none}, {grass, unclear}} -> {0.9, 0.1}, {{metal, none}, {metal, footsteps}} -> {0.1, 0.9}, {{water, splashing}, {water, unclear}} -> {0.9, 0.1}, {{door, creaking}, {door, unclear}} -> {0.9, 0.1}}, {27, 5}];

Visualize a estrutura do nível.

mostre o input completo de Wolfram Languageoculte o input

In[5]:=

X edges = {27 <-> 1, 1 <-> 2, 2 <-> 3, 3 <-> 4, 3 <-> 7, 4 <-> 5, 5 <-> 25, 25 <-> 24, 24 <-> 22, 22 <-> 21, 21 <-> 23, 21 <-> 20, 20 <-> 19, 19 <-> 18, 18 <-> 17, 17 <-> 7, 17 <-> 8, 18 <-> 9, 19 <-> 10, 10 <-> 9, 9 <-> 8, 8 <-> 7, 10 <-> 26, 10 <-> 14, 9 <-> 14, 8 <-> 13, 8 <-> 12, 14 <-> 15, 15 <-> 16, 14 <-> 13, 13 <-> 12, 13 <-> 11, 12 <-> 11, 11 <-> 6, 6 <-> 1};

In[6]:=

X regions = Range[27] /. MapThread[vert : #1 :> Style[vert, #2] &, colors];

In[7]:=

X gr = Graph[regions, edges, VertexSize -> Large, VertexLabels -> Placed["Name", Above], VertexShapeFunction -> "Square"]

Out[7]=

Suponha que o jogador entra com a mesma probabilidade através de uma das portas.

In[8]:=

X p0 = SparseArray[{door -> 1/Length[door]}, 27];

O jogador permanece com uma probabilidade de 10% na região atual, ou de outro modo é igual a probabilidade de se mover para qualquer das regiões vizinhas.

In[9]:=

X adjm = AdjacencyMatrix[gr]; tm = 0.9 adjm/Total[adjm, {2}] + 0.1 IdentityMatrix[27];

In[10]:=

X hmm = HiddenMarkovProcess[p0, tm, em];

O agente ouve a seguinte sequência de ruídos.

In[11]:=

X obs = {creaking, none, footsteps, none, none, splashing, splashing, footsteps, splashing};

Isso mostra que, provavelmente, o jogador entrou pela porta marcada como 27 e está atualmente na região 7.

In[12]:=

X FindHiddenMarkovStates[obs, hmm] /. MapThread[v : #1 :> Framed[v, FrameStyle -> #2] &, colors]

Out[12]=