Rastree el movimiento del jugador en un juego de disparos en primera persona 

En un juego de disparos en primera persona, un agente se oculta dentro de un nivel y espera saltar sobre el jugador. El agente no puede ver al jugador, pero puede escuchar lo que está haciendo y luego puede coincidir esa información con su conocimiento de la disposición del nivel para estimar la posición del jugador. Considere una disposición de 27 regiones de cuatro tipos: césped, rejillas de metal, agua y puertas a portales.

muestre la entrada completa de Wolfram Languageoculte la entrada

In[1]:=

X grass = Alternatives[1, 2, 4, 5, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20]; metal = Alternatives[3, 6, 21, 22, 24, 25]; water = Alternatives[7, 8, 9, 10]; door = Alternatives[23, 26, 27];

Asigne colores a los distintos tipos de regiones.

In[2]:=

X colors = Transpose[{{grass, Green}, {metal, Gray}, {water, Blue}, {door, Brown}}];

Caminar sobre los diferentes tipos de terreno produce diferentes tipos de sonidos.

In[3]:=

X {none, footsteps, splashing, creaking, unclear} = Range[5];

Las probabilidades de eliminar los sonidos depende del tipo de terreno.

In[4]:=

X em = SparseArray[{ {{grass, none}, {grass, unclear}} -> {0.9, 0.1}, {{metal, none}, {metal, footsteps}} -> {0.1, 0.9}, {{water, splashing}, {water, unclear}} -> {0.9, 0.1}, {{door, creaking}, {door, unclear}} -> {0.9, 0.1}}, {27, 5}];

Visualice la distribución del nivel.

muestre la entrada completa de Wolfram Languageoculte la entrada

In[5]:=

X edges = {27 <-> 1, 1 <-> 2, 2 <-> 3, 3 <-> 4, 3 <-> 7, 4 <-> 5, 5 <-> 25, 25 <-> 24, 24 <-> 22, 22 <-> 21, 21 <-> 23, 21 <-> 20, 20 <-> 19, 19 <-> 18, 18 <-> 17, 17 <-> 7, 17 <-> 8, 18 <-> 9, 19 <-> 10, 10 <-> 9, 9 <-> 8, 8 <-> 7, 10 <-> 26, 10 <-> 14, 9 <-> 14, 8 <-> 13, 8 <-> 12, 14 <-> 15, 15 <-> 16, 14 <-> 13, 13 <-> 12, 13 <-> 11, 12 <-> 11, 11 <-> 6, 6 <-> 1};

In[6]:=

X regions = Range[27] /. MapThread[vert : #1 :> Style[vert, #2] &, colors];

In[7]:=

X gr = Graph[regions, edges, VertexSize -> Large, VertexLabels -> Placed["Name", Above], VertexShapeFunction -> "Square"]

Out[7]=

Asuma que el jugador entra a través de las puertas con igual probabilidad.

In[8]:=

X p0 = SparseArray[{door -> 1/Length[door]}, 27];

El jugador permanece en la región actual con una probabilidad del 10% y, de otra manera, es igualmente probable moverse a cualquier región vecina.

In[9]:=

X adjm = AdjacencyMatrix[gr]; tm = 0.9 adjm/Total[adjm, {2}] + 0.1 IdentityMatrix[27];

In[10]:=

X hmm = HiddenMarkovProcess[p0, tm, em];

El agente escucha la siguiente secuencia de ruidos.

In[11]:=

X obs = {creaking, none, footsteps, none, none, splashing, splashing, footsteps, splashing};

Esto muestra que muy probablemente el jugador entró a través de la puerta 27 y está actualmente en la región 7.

In[12]:=

X FindHiddenMarkovStates[obs, hmm] /. MapThread[v : #1 :> Framed[v, FrameStyle -> #2] &, colors]

Out[12]=