GARCHProcess 中的波动率聚集 

广义自回归条件异方差过程 GARCHProcess 用于描述展示波动率聚集现象的时间序列. 该显现表现为大幅度变化后有跟随任何符号方向的大幅度变化的倾向，且小幅度变化后有跟随小幅度变化的倾向.

模拟一个 GARCHProcess.

In[1]:=

X garch\[ScriptCapitalP] = GARCHProcess[.5, {.6}, {.3}]; BlockRandom[SeedRandom[44]; data = RandomFunction[garch\[ScriptCapitalP], {0, 10^6}]];

绘制窗长度为10的移动标准偏差.

In[2]:=

X var = MovingMap[StandardDeviation, data, 10]; ListLinePlot[TimeSeriesResample[var, 100], PlotRange -> {0, 40}, Ticks -> {Table[{10^5 k, k}, {k, 10}], Automatic}, AxesLabel -> {"\[Times] 10^5", None}, ImageSize -> Medium]

Out[2]=

假设给定过程以前时间值近似于给定数值，定义计算标准偏差的函数.

显示完整的 Wolfram 语言输入隐藏输入

In[3]:=

X cfBinarySearch = Compile[{{list, _Real, 1}, {elem, _Real}}, Module[{n0 = 1, n1 = Length[list], m = 1, lm}, While[n0 < n1, m = Quotient[n0 + n1, 2]; lm = Part[list, m]; If[lm == elem, Break[]]; If[lm < elem, n0 = m + 1, n1 = m - 1]]; m], RuntimeOptions -> "Speed", RuntimeAttributes -> Listable];

In[4]:=

X condVar[pd_, v_] := Module[{cd, n, var, p0, p1}, {p0, p1} = cfBinarySearch[pd[[All, 1]], v + Abs[v] {-0.1, 0.1}]; cd = Take[pd, {p0 - 1, p1}]; n = Length[cd]; If[n > 10, {Mean[cd[[All, 1]]], StandardDeviation[cd[[All, 2]]]}, {Indeterminate, Indeterminate}]]

将条件标准偏差作为条件值的函数进行估计.

In[5]:=

X Quantile[data, {0, 0.01, 0.05, 0.95, 0.99, 1}]

Out[5]=

In[6]:=

X vlist = Join[#, -#] &[{1, 2, 4, 6, 8, 10, 15, 20, 25, 30, 35, 40}]; Block[{pd = SortBy[Partition[data["Values"], 2, 1], First]}, sdEst = Table[condVar[pd, v], {v, Sort[vlist]}]];

In[7]:=

X ListLinePlot[SortBy[sdEst, First]]

Out[7]=

与条件标准偏差为的常量 ARMA 过程的样本图进行比较.

In[8]:=

X arma\[ScriptCapitalP] = ARMAProcess[{.6, 0.1}, {.3}, 1]; BlockRandom[SeedRandom[44]; data2 = RandomFunction[arma\[ScriptCapitalP], {10^6}]];

In[9]:=

X Quantile[data2, {0, 0.01, 0.05, 0.25, 0.75, 0.95, 0.99, 1}]

Out[9]=

In[10]:=

X vlist = Join[#, -#] &[{0.5, 1, 2, 3, 4, 5}]; Block[{pd2 = SortBy[Partition[data2["Values"], 2, 1], First]}, sdEst2 = Table[condVar[pd2, v], {v, Sort[vlist]}]];

In[11]:=

X ListLinePlot[SortBy[sdEst2, First], PlotRange -> {0, 2}]

Out[11]=