Wolfram Language™

Función de densidad de probabilidad para Producto/Cociente de variables aleatorias

Encuentre la función de densidad de probabilidad de la relación de los más pequeños a los más grandes entre trazos independientes de BetaDistribution[2, 3].

In[1]:=

n = 5; pdf = PDF[ TransformedDistribution[ min/max, {min, max} \[Distributed] OrderDistribution[{BetaDistribution[2, 3], n}, {1, n}]], u]

Out[1]=

Visualice la densidad.

In[2]:=

Plot[pdf, {u, 0, 1}, PlotRange -> All, Filling -> Axis, PlotTheme -> "Detailed", ImageSize -> Medium, PlotLegends -> None]

Out[2]=

Compute la función de densidad de probabilidad del producto de dos distribuciones triangulares.

In[3]:=

pdf2 = PDF[ TransformedDistribution[ x1 x2, {x1 \[Distributed] TriangularDistribution[{-1, 2}, -1], x2 \[Distributed] TriangularDistribution[{-4, 3}, 2]}], u]

Out[3]=

In[4]:=

Plot[pdf2, {u, -4, 4}, Exclusions -> None, Filling -> Axis, PlotTheme -> "Detailed", ImageSize -> "Medium", PlotLegends -> None, PlotRange -> All]

Out[4]=

Encuentre la función de densidad de probabilidad del cociente de dos variables aleatorias independientes normales.

In[5]:=

pdf3 = PDF[ TransformedDistribution[ z1/z2, {z1 \[Distributed] NormalDistribution[], z2 \[Distributed] NormalDistribution[\[Mu], 1]}], x]

Out[5]=

La distribución tiene una cola pesada para cualquier valor fijo de .

In[6]:=

Series[Exp[\[Mu]^2/2] pdf3, {x, Infinity, 8}, Assumptions -> \[Mu] > 0] // Expand

Out[6]=

In[7]:=

Plot[Evaluate[ pdf3 /. {{\[Mu] -> 0}, {\[Mu] -> 1}, {\[Mu] -> 3}, {\[Mu] -> 5}}], {x, -2, 2}, PlotLegends -> {"\[Mu] = 0", "\[Mu] = 1", "\[Mu] = 3", "\[Mu] = 5"}, PlotRange -> All, PlotTheme -> "Detailed", ImageSize -> "Medium"]

Out[7]=