Solucione um problema de valor para a equação de ondas

Especifique a equação de ondas com a unidade de velocidade de propagação.

In[1]:=

weqn = D[u[x, t], {t, 2}] == D[u[x, t], {x, 2}];

Estabeleça as condições iniciais para a equação.

In[2]:=

ic = {u[x, 0] == E^(-x^2), Derivative[0, 1][u][x, 0] == 1};

Resolva o problema de valor inicial.

In[3]:=

DSolveValue[{weqn, ic}, u[x, t], {x, t}]

Out[3]=

A onda se propaga ao longo de um par de direções características.

In[4]:=

DSolveValue[{weqn, ic}, u[x, t], {x, t}]; Plot3D[%, {x, -7, 7}, {t, 0, 4}, Mesh -> None]

Out[4]=

Resolva o problema de valor inicial com dados definidos por partes.

In[5]:=

ic = {u[x, 0] == UnitBox[x] + UnitTriangle[x/3], Derivative[0, 1][u][x, 0] == 0};

In[6]:=

DSolveValue[ {weqn, ic}, u[x, t], {x, t}]

Out[6]=

As descontinuidades nos dados iniciais são propagados ao longo das direções características.

In[7]:=

DSolveValue[ {weqn, ic}, u[x, t], {x, t}]; Plot3D[%, {x, -7, 7}, {t, 0, 4}, PlotRange -> All, Mesh -> None, ExclusionsStyle -> Red]

Out[7]=

Resolva o problema de valor inicial com uma soma de funções exponenciais como dados iniciais.

In[8]:=

ic = {u[x, 0] == E^(-(x - 6)^2) + E^(-(x + 6)^2), Derivative[0, 1][u][x, 0] == 1/2};

In[9]:=

sol = DSolveValue[ {weqn, ic}, u[x, t], {x, t}]

Out[9]=

Visualizar a solução.

In[10]:=

Plot3D[sol, {x, -30, 30}, {t, 0, 20}, PlotRange -> All, Mesh -> None, PlotPoints -> 30]

Out[10]=