Wolfram Language™

Aspirin herstellen

Aspirin ist eines der am meisten verwendeten Medikamente zur Behandlung von Schmerzen, Fieber und Entzündungen. Es kann aus einer Reaktion aus gleichen Mengen von Salicylsäure und Essigsäureanhydrid hergestellt werden. In diesem Beispiel werden die chemischen Daten aus der Wolfram Knowledgebase gemeinsam mit dem Quantity-Framework, Entitätsgruppen und Entitätsinstanzen verwendet, um die chemische Herstellung von Aspirin zu untersuchen.

Diese EntityGroup repräsentiert eine typische Labor-Charge für eine Herstellung von 100 Millimol Aspirin.

In[1]:=

reactants = EntityGroup[{EntityInstance[Entity["Chemical", "SalicylicAcid"], Quantity[0.1, "Moles"]], EntityInstance[Entity["Chemical", "AceticAnhydride"], Quantity[0.1, "Moles"]]}]

Out[1]=

Berechnen Sie die Gesamtmasse dieser Charge.

In[2]:=

mass = reactants["AbsoluteMass"]

Out[2]=

Da Essigsäureanhydrid eine Flüssigkeit ist, empfiehlt es sich zu wissen, wie viele Milliliter genau benötigt werden.

In[3]:=

UnitConvert[ EntityInstance[Entity["Chemical", "AceticAnhydride"], Quantity[0.1, "Moles"]]["AbsoluteVolume"], "Milliliter"]

Out[3]=

Unter der Annahme einer stöchiometrischen, d.h. einer (theoretischen) quantitativen Reaktion, ergibt sich so eine Menge von 100 mmol Aspirin. In der Praxis werden jedoch nur 90% gewonnen.

In[4]:=

EntityInstance[Entity["Chemical", "Aspirin"], 0.9*Quantity[0.1, "Moles"]]["AbsoluteMass"]

Out[4]=

Ermitteln Sie Art und Anzahl der Atome, aus dem das Aspirin-Molekül besteht.

In[5]:=

elem = Entity["Chemical", "Aspirin"]["ElementCounts"]

Out[5]=

Fassen Sie die genaue jeweilige Anzahl dieser Atome in einem gruppierten Entitätsausdruck zusammen.

In[6]:=

atomAssemble = EntityGroup[ MapThread[EntityCopies[#1, #2] &, {Keys[elem], Values[elem]}]]

Out[6]=

In[7]:=

atomicmass = atomAssemble["AtomicMass"]

Out[7]=

Die Gesamtatommasse dieser Entitätsgruppe stimmt wie erwartet mit der molaren Masse des gesamten Moleküls überein.

In[8]:=

molarmass = Entity["Chemical", "Aspirin"][ EntityProperty["Chemical", "MolarMass"]]

Out[8]=

In[9]:=

Equal @@ QuantityMagnitude /@ {atomicmass, molarmass}

Out[9]=

Es gibt jedoch zahlreiche isotopische Kombinationen, jede von ihnen mit geringfügig anderer Gesamtmasse.

In[10]:=

stableIsotopes = #[EntityProperty["Element", "StableIsotopes"]] & /@ Keys[elem]

Out[10]=

Diese Gruppe besteht nur aus den Standard-Isotopen (dem sogenannten „Hauption“).

In[11]:=

EntityGroup[{EntityCopies[Entity["Isotope", "C12"], 9], EntityCopies[Entity["Isotope", "H1"], 8], EntityCopies[Entity["Isotope", "O16"], 4]}]["AtomicMass"]

Out[11]=

Die Wahrscheinlichkeit des Auftretens eines Moleküls mit solcher Zusammensetzung liegt bei unter 90%. Nichtdestoweniger würde es in einem Massespektrum die prominenteste Molekülspitze verkörpern.

In[12]:=

Times @@ MapThread[(QuantityMagnitude[#1[ EntityProperty["Isotope", "IsotopeAbundance"]], "PureUnities"])^#2 &, {stableIsotopes[[All, 1]], Values[elem]}]

Out[12]=