Wolfram Language™

Visualisieren Sie die Wolfram Language

Die Struktur der Wolfram Language und ihrer Beziehung mit der Wolfram Knowledgebase kann auf unterschiedliche Art und Weise visualisiert werden. In diesem Beispiel können Sie eine Schlagwortwolke aus Begriffen, die sich auf Aspekte dieser Beziehung beziehen, untersuchen und diese aus Outputs der Dokumentation zusammensetzen. Sie können die Orte und Zeitangaben in Zusammenhang mit Personen, die namensgebend für Wolfram Language-Symbole sind, visualisieren.

Erstellen Sie eine Schlagwortwolke aus Begriffen, die in der WolframLanguageData-Dokumentation vorkommen.

In[1]:=

WordCloud[ DeleteStopwords[ Flatten[TextWords[ WolframLanguageData["WolframLanguageData", "TextStrings"]]]]]

Out[1]=

Erstellen Sie eine Collage der Outputs einfacher Dokumentations-Beispiele für Plot.

In[2]:=

ImageCollage[ Cases[WolframLanguageData["Plot", "DocumentationBasicExamples"], c : Cell[_, "Output", ___] :> Rasterize[RawBoxes[c]], \[Infinity]], ImagePadding -> 10, Background -> Transparent]

Out[2]=

Erstellen Sie eine Collage aller Graphik-Outputs von Dokumentations-Beispielen für Plot.

In[3]:=

evaluate[l_List] := Module[{p}, p = l /. RawBoxes[Cell[BoxData[wlc_], "Input", ___]] :> ToExpression[wlc, StandardForm, Hold]; Block[Evaluate[ Select[Union[Cases[p, _Symbol, {-1}]], Quiet[Context[#] === "Global`"] &]], ReleaseHold /@ p]]

In[4]:=

ImageCollage[ Rasterize[#, ImageSize -> 100] & /@ Cases[Flatten[ evaluate /@ Flatten[WolframLanguageData["Plot", "DocumentationExampleInputs"][[All, -1]], 1]], _Graphics], ImagePadding -> 2] // Quiet

Out[4]=

Ermitteln Sie Bilder von Personen, die mit dem LaplacianGaussianFilter-Symbol der Wolfram Language assoziiert sind.

In[5]:=

ImageAssemble[ PersonData[ WolframLanguageData["LaplacianGaussianFilter", "EponymousPeople"], "Image"]]

Out[5]=

Extrahieren Sie Personen, nach denen Wolfram Language-Symbole benannt sind.

In[6]:=

people = DeleteCases[ Union[Flatten[ WolframLanguageData[All, "EponymousPeople"]]], _Missing];

Rufen Sie Information über ihre Geburtsorte ab.

In[7]:=

placedata = DeleteCases[ PersonData[ people, {"Image", "BirthPlace", "Name"}], {_, _Missing, _}];

Erzeugen Sie eine Weltkarte mit diesen Personen und ihren Geburtsorten.

In[8]:=

GeoGraphics[ Tooltip[Point[#2], Column[DeleteCases[{##} /. e_Entity :> CommonName[e], _Missing]]] & @@@ placedata] // Quiet

Out[8]=

Extrahieren Sie die Geburts- und Todestage der Personen, nach denen Wolfram Language-Symbole benannt sind.

In[9]:=

timedata = Block[{EntityFramework`$EntityValueBatchSize = 300}, DeleteCases[ PersonData[ people, {"BirthDate", "DeathDate", "Name", "Image"}], {_Missing, __}]];

Erstellen Sie eine Zeitleiste.

In[10]:=

formatdates[d1_, d2_] := Row[Riffle[Switch[#, Missing["Alive"], "present", _Missing, "????", _, DateString[#, {"MonthName", " ", "DayShort", ", ", "Year"}] ] & /@ {d1, d2}, "-"]]

In[11]:=

TimelinePlot[ Association @@ ((Tooltip[StringSplit[#3, " "][[-1]], Column[{#4, #3, formatdates[#1, #2]}]] -> #1) & @@@ Select[timedata, #[[1]] > DateObject[{1800}] &])]

Out[11]=