Beobachterentwürfe anhand von Rückführungslinearisierung 

Rückführungslinearisierung ermöglicht außerdem den Entwurf nichtlinearer Beobachter unter der Verwendung linearer Verfahren. Schätzen Sie den Gierwinkel und die Giergeschwindigkeit für ein Schiff mit Rumpflänge und Geschwindigkeit , basierend auf dem Norrbin-Modell und unter der Verwendung der Rückführungslinearisierung. »

In[1]:=

X pars = {Subscript[n, 3] -> 1, Subscript[n, 1] -> 1, Subscript[n, 2] -> 0, Subscript[n, 0] -> 0};

In[2]:=

X asys = AffineStateSpaceModel[(2 l/v) \[Psi]''[t] + Subscript[n, 3] \[Psi]'[t]^3 + Subscript[n, 2] \[Psi]'[t]^2 + Subscript[n, 1] \[Psi]'[t] + Subscript[n, 0] == (v/l) \[Delta][t], \[Psi][t], \[Delta][t], \[Psi][t], t] /. pars /. {l -> 45}

Out[2]=

Die Rückführung ist in diesem Modell vollständig linearisierbar.

In[3]:=

X \[ScriptCapitalF] = FeedbackLinearize[asys]

Out[3]=

Berechnen Sie die Beobachterverstärkung via Polplatzierung.

In[4]:=

X EstimatorGains[\[ScriptCapitalF]["LinearSystem"], {-2 + I, -2 - I}]

Out[4]=

Arbeiten Sie den nichtlinearen Beobachter aus.

In[5]:=

X EstimatorGains[\[ScriptCapitalF]["LinearSystem"], {-2 + I, -2 - I}]; \[ScriptL] = \[ScriptCapitalF][{"OriginalSystemEstimator", %}]

Out[5]=

Stellen Sie die geschätzten Zustandstrajektorien für eine bestimmte Geschwindigkeit dar.

In[6]:=

X inp = -UnitStep[t] + UnitStep[t - 1]; ics = {-2, 1};

In[7]:=

X esr = OutputResponse[ SystemsModelDelete[\[ScriptL] /. v -> 5, None, -1], Join[{inp}, OutputResponse[{asys /. v -> 5, ics}, inp, {t, 0, 10}]], {t, 0, 10}];

In[8]:=

X Plot[esr, {t, 0, 10}, PlotStyle -> Dashed, PlotRange -> All, PlotLegends -> {"Yaw (\[Psi])", "Yaw rate (\[Psi]')"}]

Out[8]=

Berechen Sie die tatsächlichen Zustandstrajektorien.

In[9]:=

X sr = StateResponse[{asys /. v -> 5, ics}, inp, {t, 0, 10}]

Out[9]=

Vergleichen Sie die tatsächlichen und geschätzen Werte für Gierwinkel und Giergeschwindigkeit.

In[10]:=

X Table[Plot[{sr[[i]], esr[[i]]}, {t, 0, 5}, PlotStyle -> {Automatic, Dashed}, PlotLegends -> {"Actual", "Estimated"}, PlotRange -> All, PlotLabel -> Switch[i, 1, "Yaw Angle", _, "Yaw rate"]], {i, {1, 2}}]

Out[10]=