Estimador de diseño usando linealización de retroacción 

La linealización de retroacción también permite el diseño de estimadores no lineales usando técnicas lineales. Calcule el ángulo de orientación y el índice de orientación para una embarcación con longitud de casco y velocidad , basado en el modelo de Norrbin y usando linealización de retroacción. »

In[1]:=

X pars = {Subscript[n, 3] -> 1, Subscript[n, 1] -> 1, Subscript[n, 2] -> 0, Subscript[n, 0] -> 0};

In[2]:=

X asys = AffineStateSpaceModel[(2 l/v) \[Psi]''[t] + Subscript[n, 3] \[Psi]'[t]^3 + Subscript[n, 2] \[Psi]'[t]^2 + Subscript[n, 1] \[Psi]'[t] + Subscript[n, 0] == (v/l) \[Delta][t], \[Psi][t], \[Delta][t], \[Psi][t], t] /. pars /. {l -> 45}

Out[2]=

El modelo es completamente linealizable por retroacción.

In[3]:=

X \[ScriptCapitalF] = FeedbackLinearize[asys]

Out[3]=

Calcule un conjunto de ganancias de estimador usando la ubicación de los polos.

In[4]:=

X EstimatorGains[\[ScriptCapitalF]["LinearSystem"], {-2 + I, -2 - I}]

Out[4]=

Arme un estimador no lineal.

In[5]:=

X EstimatorGains[\[ScriptCapitalF]["LinearSystem"], {-2 + I, -2 - I}]; \[ScriptL] = \[ScriptCapitalF][{"OriginalSystemEstimator", %}]

Out[5]=

Grafique las trayectorias de estado estimadas para una velocidad de embarcación determinada.

In[6]:=

X inp = -UnitStep[t] + UnitStep[t - 1]; ics = {-2, 1};

In[7]:=

X esr = OutputResponse[ SystemsModelDelete[\[ScriptL] /. v -> 5, None, -1], Join[{inp}, OutputResponse[{asys /. v -> 5, ics}, inp, {t, 0, 10}]], {t, 0, 10}];

In[8]:=

X Plot[esr, {t, 0, 10}, PlotStyle -> Dashed, PlotRange -> All, PlotLegends -> {"Yaw (\[Psi])", "Yaw rate (\[Psi]')"}]

Out[8]=

Calcule las trayectorias de estado actuales.

In[9]:=

X sr = StateResponse[{asys /. v -> 5, ics}, inp, {t, 0, 10}]

Out[9]=

Compare los ángulos y tasas de orientación actuales y estimadas.

In[10]:=

X Table[Plot[{sr[[i]], esr[[i]]}, {t, 0, 5}, PlotStyle -> {Automatic, Dashed}, PlotLegends -> {"Actual", "Estimated"}, PlotRange -> All, PlotLabel -> Switch[i, 1, "Yaw Angle", _, "Yaw rate"]], {i, {1, 2}}]

Out[10]=