Projeto de estimador usando linearização por realimentação 

Linearização por realimentação também permite o projeto de estimadores não lineares usando técnicas lineares. Calcule o ângulo de guinada e a velocidade angular de guinada para um navio com casco de comprimento e velocidade , com base no modelo de Norrbin e usando linearização por realimentação. »

In[1]:=

X pars = {Subscript[n, 3] -> 1, Subscript[n, 1] -> 1, Subscript[n, 2] -> 0, Subscript[n, 0] -> 0};

In[2]:=

X asys = AffineStateSpaceModel[(2 l/v) \[Psi]''[t] + Subscript[n, 3] \[Psi]'[t]^3 + Subscript[n, 2] \[Psi]'[t]^2 + Subscript[n, 1] \[Psi]'[t] + Subscript[n, 0] == (v/l) \[Delta][t], \[Psi][t], \[Delta][t], \[Psi][t], t] /. pars /. {l -> 45}

Out[2]=

O modelo é completamente linearizável por realimentação.

In[3]:=

X \[ScriptCapitalF] = FeedbackLinearize[asys]

Out[3]=

Calcule um conjunto de ganhos do estimador utilizando alocação de pólos.

In[4]:=

X EstimatorGains[\[ScriptCapitalF]["LinearSystem"], {-2 + I, -2 - I}]

Out[4]=

Monte o estimador não linear.

In[5]:=

X EstimatorGains[\[ScriptCapitalF]["LinearSystem"], {-2 + I, -2 - I}]; \[ScriptL] = \[ScriptCapitalF][{"OriginalSystemEstimator", %}]

Out[5]=

Projete as trajetórias de estado estimadas para uma velocidade específica do navio.

In[6]:=

X inp = -UnitStep[t] + UnitStep[t - 1]; ics = {-2, 1};

In[7]:=

X esr = OutputResponse[ SystemsModelDelete[\[ScriptL] /. v -> 5, None, -1], Join[{inp}, OutputResponse[{asys /. v -> 5, ics}, inp, {t, 0, 10}]], {t, 0, 10}];

In[8]:=

X Plot[esr, {t, 0, 10}, PlotStyle -> Dashed, PlotRange -> All, PlotLegends -> {"Yaw (\[Psi])", "Yaw rate (\[Psi]')"}]

Out[8]=

Calcule as trajetórias de estado reais.

In[9]:=

X sr = StateResponse[{asys /. v -> 5, ics}, inp, {t, 0, 10}]

Out[9]=

Compare os ângulos de guinada e as velocidades angulares de guinada reais e estimadas.

In[10]:=

X Table[Plot[{sr[[i]], esr[[i]]}, {t, 0, 5}, PlotStyle -> {Automatic, Dashed}, PlotLegends -> {"Actual", "Estimated"}, PlotRange -> All, PlotLabel -> Switch[i, 1, "Yaw Angle", _, "Yaw rate"]], {i, {1, 2}}]

Out[10]=